blob: a9fa624011cb5bcc4eaf019ea98f7ab75b9309a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Maintainer: Attila Greguss <floyd0122[at]gmail[dot]com>
# armv7h and aarch64 Comaintainers needed
pkgbase=dotnet-core-6.0-bin
pkgname=(
'aspnet-runtime-6.0-bin'
'dotnet-runtime-6.0-bin'
'dotnet-sdk-6.0-bin'
'dotnet-targeting-pack-6.0-bin'
'aspnet-targeting-pack-6.0-bin'
)
pkgver=6.0.26.sdk418
_runtimever=6.0.26
_sdkver=6.0.418
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
options=('staticlibs')
source_armv7h=('https://download.visualstudio.microsoft.com/download/pr/2088d482-4a99-4dfd-96d8-01438439f088/31d073266c6d390c7082d01492c87ec2/dotnet-sdk-6.0.418-linux-arm.tar.gz')
source_aarch64=('https://download.visualstudio.microsoft.com/download/pr/487a62cc-de86-4648-bcf4-18a02b0f4ccc/669d92e679215646badef80782d32bff/dotnet-sdk-6.0.418-linux-arm64.tar.gz')
source_x86_64=('https://download.visualstudio.microsoft.com/download/pr/01292c7c-a1ec-4957-90fc-3f6a2a1e5edc/025e84c4d9bd4aeb003d4f07b42e9159/dotnet-sdk-6.0.418-linux-x64.tar.gz')
sha512sums_armv7h=('f9e978268753d58c6b33b295f48b91a47e81b520ea89c29d561cf8247a709ce67efb2a7e4cd7df32a8d6b938606566e5ab9d2c99babcaa5b68662b1e27b71e30')
sha512sums_aarch64=('2848db109c65dc284320f680c13b498789f944f3474788548c0bf15d333020cf9b8286348bacda9af56e1dea6b56590ff24669de7ed5eaa31906f4710cabc6e1')
sha512sums_x86_64=('24d705157ae51ed5ec5ff267c76474d2ff71b0e56693f700de456321f15212a7791291b95770522a976434f5220e5c03b042f41755a0b6e9854abf73cd51e299')
package_dotnet-runtime-6.0-bin() {
pkgdesc='The .NET Core runtime (binary)'
depends=(
"dotnet-host>=${_runtimever}"
'gcc-libs'
'glibc'
'icu'
'libgssapi_krb5.so'
'libunwind'
'zlib'
'openssl'
)
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${_runtimever}" "dotnet-runtime-6.0")
conflicts=("dotnet-runtime=${_runtimever}" "dotnet-runtime-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-runtime-6.0-bin
}
package_aspnet-runtime-6.0-bin() {
pkgdesc='The ASP.NET Core runtime (binary)'
depends=('dotnet-runtime-6.0-bin')
provides=("aspnet-runtime=${_runtimever}" "aspnet-runtime-6.0")
conflicts=("aspnet-runtime=${_runtimever}" "aspnet-runtime-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-runtime-6.0-bin
}
package_dotnet-sdk-6.0-bin() {
pkgdesc='The .NET Core SDK (binary)'
depends=(
'glibc'
'gcc-libs'
'dotnet-runtime-6.0-bin'
'dotnet-targeting-pack-6.0-bin'
'netstandard-targeting-pack')
optdepends=('aspnet-targeting-pack-bin: Build ASP.NET Core applications')
provides=("dotnet-sdk=${pkgver}" "dotnet-sdk-6.0")
conflicts=("dotnet-sdk=${pkgver}" "dotnet-sdk-6.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet,licenses}
cp -dr --no-preserve='ownership' sdk sdk-manifests templates "${pkgdir}"/usr/share/dotnet/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-sdk-6.0-bin
}
package_dotnet-targeting-pack-6.0-bin() {
pkgdesc='The .NET Core targeting pack (binary)'
depends=(
'netstandard-targeting-pack'
)
provides=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-6.0)
conflicts=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-6.0)
if [ $CARCH = 'x86_64' ]; then msarch=x64;
elif [ $CARCH = 'armv7h' ]; then msarch=arm;
elif [ $CARCH = 'aarch64' ]; then msarch=arm64; fi
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.NETCore.App.{Host.linux-${msarch},Ref} "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-targeting-pack-6.0-bin
}
package_aspnet-targeting-pack-6.0-bin() {
pkgdesc='The ASP.NET Core targeting pack (binary)'
depends=(
'dotnet-targeting-pack-6.0-bin'
)
provides=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-6.0)
conflicts=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-6.0)
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.AspNetCore.App.Ref "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-targeting-pack-6.0-bin
}
|