blob: 8f8dd701a550b4224452e54298049491bedfa8f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Attila Greguss <floyd0122[at]gmail[dot]com>
pkgbase=dotnet-core-bin
pkgname=('dotnet-host-bin' 'aspnet-runtime-bin' 'dotnet-runtime-bin' 'dotnet-sdk-bin')
pkgver=3.1.3.sdk201
_runtimever=3.1.3
_sdkver=3.1.201
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
makedepends=(
'clang' 'cmake' 'curl' 'git' 'icu' 'krb5' 'libunwind' 'lldb' 'llvm'
'lttng-ust' 'openssl' 'zlib'
)
options=('staticlibs')
source=('dotnet.sh')
sha512sums=('448e2ad41a1ac5b7adf4a17ef27d01d1f20c6d355fdb1e10b0ceb4bd6edd8b3a24874aa8c42cfcf56267a6a85c5896b5f69764e5e59526f6938ec7c9d1ec7383')
source_armv7h=('https://download.visualstudio.microsoft.com/download/pr/ccbcbf70-9911-40b1-a8cf-e018a13e720e/03c0621c6510f9c6f4cca6951f2cc1a4/dotnet-sdk-3.1.201-linux-arm.tar.gz')
source_aarch64=('https://download.visualstudio.microsoft.com/download/pr/98a2e556-bedd-46c8-b3fa-96a9f1eb9556/09f60d50e3cbba0aa16d48ceec9dcb0b/dotnet-sdk-3.1.201-linux-arm64.tar.gz')
source_x86_64=('https://download.visualstudio.microsoft.com/download/pr/f65a8eb0-4537-4e69-8ff3-1a80a80d9341/cc0ca9ff8b9634f3d9780ec5915c1c66/dotnet-sdk-3.1.201-linux-x64.tar.gz')
sha512sums_armv7h=('f37d0e55c9f593c6951bea5a6bb1ea3194486956efe08a2a0f266b419d912cdcbf4ac279358976f0bfa1fe560c333ca5d5437f8e8c718bb5963991e4395e0cd7')
sha512sums_aarch64=('2f4f6b7ae55802b0beaf5d62bcb64f23ce132c9e08d8ce0f0af8d9b0b1b2c2629b1d4e805e83f831575c9968a86d1495dfa5292d2592af0cd1ae4a385daf42e7')
sha512sums_x86_64=('934bf29734776331691a4724f2174c4e9d2d1dde160f18397fd01abf0f96f2ec1bdd2874db9f0e25dce6993d527ea9c19031a0e67383fd813dcfcb9552ea0c70')
package_dotnet-host-bin() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (binary)'
provides=("dotnet-host")
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/usr/{bin,lib,share/{dotnet,licenses/dotnet-host}}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/usr/share/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host
install -Dm 755 "${srcdir}"/dotnet.sh "${pkgdir}"/usr/share/dotnet
ln -sf /usr/share/dotnet/dotnet.sh "${pkgdir}"/usr/bin/dotnet
ln -sf /usr/share/dotnet/host/fxr/"${_runtimever}"/libhostfxr.so "${pkgdir}"/usr/lib/libhostfxr.so
}
package_dotnet-runtime-bin() {
pkgdesc='The .NET Core runtime (binary)'
depends=('dotnet-host' 'icu' 'krb5' 'libunwind' 'openssl' 'zlib'
'libcurl.so')
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime-3.1" "dotnet-runtime=${pkgver}")
conflicts=("dotnet-runtime-3.1")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-runtime
}
package_aspnet-runtime-bin() {
pkgdesc='The ASP.NET Core runtime (binary)'
depends=('dotnet-runtime-3.1')
provides=("aspnet-runtime-3.1" "aspnet-runtime=${pkgver}")
conflicts=("aspnet-runtime-3.1")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-runtime
}
package_dotnet-sdk-bin() {
pkgdesc='The .NET Core SDK (binary)'
depends=('dotnet-runtime-3.1')
provides=("dotnet-sdk-3.1" "dotnet-sdk=${pkgver}")
conflicts=("dotnet-sdk-3.1")
install -dm 755 "${pkgdir}"/usr/share/{dotnet,licenses}
cp -dr --no-preserve='ownership' packs sdk templates "${pkgdir}"/usr/share/dotnet/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-sdk
}
|