blob: 982915cf069c7270a2cb8640c46b8d17dfa529b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Max Liebkies <mail@maxliebkies.de>
pkgbase=dotnet-core-preview
pkgname=('dotnet-host-preview' 'dotnet-runtime-preview' 'aspnet-runtime-preview' 'dotnet-sdk-preview')
pkgver=3.0.0+100+preview.011568
pkgrel=1
arch=('x86_64')
url='https://www.microsoft.com/net/core'
license=('MIT')
makedepends=(
'clang' 'cmake' 'curl' 'git' 'icu' 'krb5' 'libunwind' 'lldb' 'llvm'
'lttng-ust' 'openssl' 'zlib'
)
options=('staticlibs')
source=(
'https://download.visualstudio.microsoft.com/download/pr/7e4b403c-34b3-4b3e-807c-d064a7857fe8/95c738f08e163f27867e38c602a433a1/dotnet-sdk-3.0.100-preview5-011568-linux-x64.tar.gz'
'https://download.visualstudio.microsoft.com/download/pr/cd52bfa4-0260-479c-a32d-b4435c8ccda8/943c20feec33b778685d733064d8ddb1/aspnetcore-runtime-3.0.0-preview5-19227-01-linux-x64.tar.gz'
'dotnet.sh'
)
sha256sums=('24178c79c280b67068961dcec1db93e59b006b7dcbf4e860efd140661868a47e'
'b16c4de7f32eef1508ab0e6b6d378459feea22bd0f477a2c35d8c4246422288e'
'f4cb02490234b853946477f82514f0c6247b55b08b2e85fae98e99a6e6974edd')
package_dotnet-host-preview() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (preview)'
provides=('dotnet-host')
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses/dotnet-host-preview}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/opt/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host-preview
install -Dm 755 "${srcdir}"/dotnet.sh "${pkgdir}"/usr/bin/dotnet
}
package_dotnet-runtime-preview() {
pkgdesc='The .NET Core runtime (preview)'
depends=('dotnet-host-preview' 'icu' 'krb5' 'libunwind' 'openssl' 'zlib'
'libcurl.so')
optdepends=('lttng-ust: CoreCLR tracing')
provides=('dotnet-runtime-3.0')
conflicts=('dotnet-runtime-3.0')
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-runtime-preview
}
package_aspnet-runtime-preview() {
pkgdesc='The ASP.NET Core runtime (preview)'
depends=('dotnet-runtime-preview')
provides=('aspnet-runtime-3.0')
conflicts=('aspnet-runtime-3.0')
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/aspnet-runtime-preview
}
package_dotnet-sdk-preview() {
pkgdesc='The .NET Core SDK (preview)'
depends=('dotnet-runtime-preview')
provides=('dotnet-sdk-3.0')
conflicts=('dotnet-sdk-3.0')
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses}
cp -dr --no-preserve='ownership' sdk "${pkgdir}"/opt/dotnet/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-sdk-preview
}
# vim: ts=2 sw=2 et:
|