blob: 98c652f7c0d569d822273eb19d595ecf6533e409 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Florian Maunier <fmauneko@dissidence.ovh>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Max Liebkies <mail@maxliebkies.de>
pkgbase=dotnet-core-preview
pkgname=('dotnet-host-preview' 'dotnet-runtime-preview' 'aspnet-runtime-preview' 'dotnet-sdk-preview')
pkgver=3.1.0+100+preview1.014459
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
makedepends=(
'clang' 'cmake' 'curl' 'git' 'icu' 'krb5' 'libunwind' 'lldb' 'llvm'
'lttng-ust' 'openssl' 'zlib'
)
options=('staticlibs')
source=(
'dotnet.sh'
)
source_x86_64=(
'https://download.visualstudio.microsoft.com/download/pr/a3cc3d8a-226d-4306-a61b-a5446fdb72ef/604e029047aec0229545e8c397a14ddb/dotnet-sdk-3.1.100-preview1-014459-linux-x64.tar.gz'
)
source_armv7h=(
'https://download.visualstudio.microsoft.com/download/pr/add0da94-569b-462d-a3d4-f29407cb9386/9570da173af00033d6b5d9aaf6603450/dotnet-sdk-3.1.100-preview1-014459-linux-arm.tar.gz'
)
source_aarch64=(
'https://download.visualstudio.microsoft.com/download/pr/3cf6ae0b-5933-461f-b32d-10bae9199a97/ff5251238265d20f07ff62181d3e2d1d/dotnet-sdk-3.1.100-preview1-014459-linux-arm64.tar.gz'
)
sha256sums=('4978b3a31a94032b425d2a2a9b5a17f506f36fb784fbfefdf2cfea9485a30f47')
sha256sums_x86_64=('e5f480b7c48b581e093567a982e39d819870f69791f24102684b9b74d5c3a332')
sha256sums_armv7h=('06b2ce08e2d171eef884bbef52aafa46098900a723da6a675be2808c2128541e')
sha256sums_aarch64=('23c0d864586d53356cf8643dbf802e9531663891e9fcb7e0e8f348416386ae05')
package_dotnet-host-preview() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (preview)'
provides=("dotnet-host=${pkgver%+*}")
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses/dotnet-host-preview}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/opt/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host-preview
install -Dm 755 "${srcdir}"/dotnet.sh "${pkgdir}"/usr/bin/dotnet
}
package_dotnet-runtime-preview() {
pkgdesc='The .NET Core runtime (preview)'
depends=('dotnet-host-preview' 'icu' 'krb5' 'libunwind' 'openssl' 'zlib'
'libcurl.so')
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-runtime-preview
}
package_aspnet-runtime-preview() {
pkgdesc='The ASP.NET Core runtime (preview)'
depends=('dotnet-runtime-preview')
provides=("aspnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/aspnet-runtime-preview
}
package_dotnet-sdk-preview() {
pkgdesc='The .NET Core SDK (preview)'
depends=('dotnet-runtime-preview')
provides=("dotnet-sdk=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses}
cp -dr --no-preserve='ownership' packs sdk templates "${pkgdir}"/opt/dotnet/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-sdk-preview
}
# vim: ts=2 sw=2 et:
|