blob: 5fb574d031e24c097b4977864a7d62b7fd355c17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=dotter-rs
_pkgname=dotter
pkgver=0.13.1
pkgrel=1
pkgdesc="A dotfile manager and templater written in Rust"
arch=('x86_64')
url="https://github.com/SuperCuber/dotter"
license=('Unlicense')
conflicts=("$_pkgname")
depends=('gcc-libs')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('b13ce785ee6b350d57f3ce3c153b68778c0010781d18e031083b79cdee3e4b028ebf16c678878a81023e03b75321104ae78df047419feb23a2f1764105f6658a')
prepare() {
cd "$_pkgname-$pkgver"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
mkdir completions
}
build() {
cd "$_pkgname-$pkgver"
cargo build --release --frozen
local _completion="target/release/$_pkgname gen-completions --shell"
$_completion bash > "completions/$_pkgname"
$_completion fish > "completions/$_pkgname.fish"
$_completion zsh > "completions/_$_pkgname"
}
check() {
cd "$_pkgname-$pkgver"
cargo test --frozen
}
package() {
cd "$_pkgname-$pkgver"
install -Dm 755 "target/release/$_pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 "completions/$_pkgname" -t "$pkgdir/usr/share/bash-completion/completions/"
install -Dm 644 "completions/$_pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d/"
install -Dm 644 "completions/_$_pkgname" -t "$pkgdir/usr/share/zsh/site-functions/"
}
|