summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0ada91be7cc8aa0af5e896a42e7e4444c52780fc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=doxymacs-git
pkgver=20131007
pkgrel=1
pkgdesc="Use Doxygen from within Emacs -- git version"
arch=('i686' 'x86_64')
url="http://doxymacs.sourceforge.net"
license=('GPL2')
depends=('libxml2>=2.6.13')
makedepends=('git' 'texlive-latexextra')
provides=('doxymacs')
conflicts=('doxymacs')
install=doxymacs.install
source=('git+https://github.com/sgoericke/doxymacs.git')
md5sums=('SKIP')
_gitname="doxymacs"

prepare() {
  cd ${pkgname%-git}
  sed -i 's+inline+extern inline+' c/doxymacs_parser.c
}

pkgver() {
  cd ${pkgname%-git}
  git log -1 --format="%cd" --date=short | tr -d '-'
}

build() {
  cd ${pkgname%-git}
  ./bootstrap
  CC=gcc ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname%-git}
  make DESTDIR="$pkgdir/" install
}