blob: 7dc6ff7183ef4447bd52ec2182d88a30e18ca1e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: CrocoDuck <crocoduck dot oducks at gmail dot com>
pkgname=dpf-plugins-git
pkgver=r86.0c433e4
pkgrel=1
pkgdesc="Collection of DPF-based plugins by DISTRHO. LV2, LADSPA, dssi and VST."
arch=('i686' 'x86_64')
url="http://distrho.sourceforge.net/"
license=('custom')
depends=('liblo' 'projectm')
makedepends=('git' 'wget')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
source=("${pkgname%-*}::git://github.com/DISTRHO/DPF-Plugins")
md5sums=('SKIP')
pkgver() {
cd "${pkgname%-*}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${pkgname%-*}"
make BUILD_DSSI=true BUILD_LV2=true BUILD_VST=true BUILD_JACK=true
}
package() {
cd "${pkgname%-*}"
# Install the custom license:
install -Dm 644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Install the package files:
make DESTDIR="$pkgdir/" PREFIX="/usr" install
}
|