PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=('drill-search-cli' 'drill-search-gtk')
pkgbase=drill-search
pkgver=571+45+gafc2b997
pkgrel=2
pkgdesc="Search files without indexing, but clever crawling"
arch=('x86_64')
url="https://drill.software"
license=('GPL2')
makedepends=('dmd' 'dub' 'git' 'gtk3')
_commit=afc2b9971bbfd7862624255d6bb5e00c6b1ab2b2
source=("git+https://github.com/yatima1460/Drill.git#commit=$_commit"
#source=("$pkgbase-$pkgver.tar.gz::https://github.com/yatima1460/Drill/archive/refs/tags/v$pkgver.tar.gz"
        "$pkgbase"
        "$pkgbase-gtk.desktop")
sha256sums=('SKIP'
            'b875f928546aee7855cb1db9afc8ab3f1a8a34d43de5bbd62f7076d7ba9f3917'
            '5bafb37baf608a3168abba2ab9ea174a1d0f0472f52d3222ea0a05957c997c50')

pkgver() {
  cd $srcdir/Drill
  git describe --tags | sed 's/^v//;s/-/+/g'
}

build() {
  cd $srcdir/Drill
  echo "$pkgver" > DRILL_VERSION
  dub build -b release -c CLI --force --parallel --verbose --arch="$CARCH"
  dub build -b release -c GTK --force --parallel --verbose --arch="$CARCH"
}

package_drill-search-cli() {
  pkgdesc+=" (CLI version)"
  depends=('bash')

  cd "$srcdir/Drill/Build/Drill-CLI-linux-$CARCH-release"
  install -d "$pkgdir/"{opt/$pkgname,usr/bin}
  cp -r Assets "$pkgdir/opt/$pkgname"
  install -Dm755 "$pkgname" -t "$pkgdir/opt/$pkgname"
  install -Dm755 "$srcdir/$pkgbase" "$pkgdir/usr/bin/$pkgname"
  echo "/opt/$pkgname/$pkgname" "\$@" >> "$pkgdir/usr/bin/$pkgname"
}

package_drill-search-gtk() {
  pkgdesc+=" (GTK version)"
  depends=('gtk3' 'xdg-utils')

  cd "$srcdir/Drill/Build/Drill-GTK-linux-$CARCH-release"
  install -d "$pkgdir/"{opt/$pkgname,usr/bin}
  cp -r Assets "$pkgdir/opt/$pkgname"
  install -Dm755 "$pkgname" -t "$pkgdir/opt/$pkgname"
  install -Dm755 "$srcdir/$pkgbase" "$pkgdir/usr/bin/$pkgname"
  echo "/opt/$pkgname/$pkgname" "\$@" >> "$pkgdir/usr/bin/$pkgname"
  install -Dm644 Assets/icon.svg \
    "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"
  install -Dm644 "$srcdir/$pkgname.desktop" -t \
    "$pkgdir/usr/share/applications"
}