blob: a8bbf2aa9beac8e0b382a8bc4d5c9c8ecd895d16 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=dropbear-hg
pkgver=r1818.587c76726b5f
pkgrel=1
pkgdesc="Small SSH server and client"
arch=('i686' 'x86_64')
url="https://matt.ucc.asn.au/dropbear/dropbear.html"
license=('custom')
depends=('glibc' 'pam' 'zlib')
makedepends=('mercurial')
provides=('dropbear')
conflicts=('dropbear')
source=("hg+https://hg.ucc.asn.au/dropbear/"
"dropbear.service::https://raw.githubusercontent.com/archlinux/svntogit-community/packages/dropbear/trunk/dropbear.service"
"localoptions.h::https://raw.githubusercontent.com/archlinux/svntogit-community/packages/dropbear/trunk/localoptions.h")
sha256sums=('SKIP'
'SKIP'
'SKIP')
prepare() {
cd "dropbear"
cp -f "$srcdir/localoptions.h" ./
}
pkgver() {
cd "dropbear"
printf "r%s.%s" "$(hg identify -n)" "$(hg identify -i)"
}
build() {
cd "dropbear"
autoconf
autoheader
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--enable-pam
make
}
package() {
cd "dropbear"
make DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/dropbear"
install -Dm644 "$srcdir/dropbear.service" -t "$pkgdir/usr/lib/systemd/system"
}
|