blob: d155052ae32267a1c450f5450c47f3ed14e699f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
# Contributor: Joel Teichroeb <joel@teichroeb.net>
# Contributor: Matthias Maennich < arch .at. maennich.net >
# Contributor: bruce < b_a_g99 .at. hotmail.com >
# Contributor: carstene1ns <arch carsten-teibes de>
pkgname=dropbox-cli
pkgver=2020.03.04
pkgrel=7
pkgdesc="Command line interface for Dropbox"
arch=("any")
url="http://www.${pkgname%-cli}.com"
license=("GPL")
depends=("${pkgname%-cli}" "python-gobject")
install="${pkgname}.install"
source=(
"${pkgname}-${pkgver}.py::https://linux.${pkgname%-cli}.com/packages/${pkgname%-cli}.py"
"${pkgname%-cli}d-fallback.patch"
)
sha256sums=(
"e8fecc095561bf4a30a9889e25c3afa40c01e1554f3392a3b949b02ee1cf19ca"
"9ae702ebf0699ac56fbf99c577ddaf22701dfd1c9e40d6ec5ac56475c2636f48"
)
prepare() {
cp -L "${srcdir}/${pkgname}-${pkgver}.py" "${srcdir}/${pkgname}.py"
# Patch to point to /opt/dropbox/dropboxd in case of local user does not exist
patch -Np1 -i "${srcdir}/${pkgname%-cli}d-fallback.patch"
}
package() {
install -dm755 "${pkgdir}/usr/bin"
install -Dm755 "${srcdir}/${pkgname}.py" "${pkgdir}/usr/share/${pkgname}/${pkgname}.py"
ln -s "/usr/share/${pkgname}/${pkgname}.py" "${pkgdir}/usr/bin/${pkgname}"
}
|