blob: 39c0f9aff105b96b83f923d274dd9bfc86b2efbc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: lmbbrkr <lmbbrkr at protonmail dot ch>
pkgname=dsd-louiserigherve-git
_pkgname="${pkgname%-git}"
pkgver=1.6.0.r109.g1599d5b
pkgrel=1
pkgdesc="Decoder for P25 Phase 1, D-STAR, NXDN/IDAS, ProVoice, DMR/MOTOTRBO, X2-TDMA, dPMR (LouisErigHerve's fork)."
arch=('x86_64')
url="https://github.com/LouisErigHerve/dsd"
license=('GPL2' 'ISC')
depends=('gcc-libs' 'glibc' 'itpp' 'libsndfile' 'mbelib' 'portaudio')
makedepends=('cmake' 'git')
provides=("${_pkgname}" 'dsd')
conflicts=("${_pkgname}" 'dsd' 'dsd-git')
source=("${_pkgname}::git+${url}")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
printf "%s" "$(HOME=/dev/null git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
}
build() {
cd "${_pkgname}"
cmake -B build ./ \
-Wno-dev \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make -C build
}
package() {
cd "${_pkgname}"
make -C build DESTDIR="${pkgdir}/" install
install -Dm644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|