blob: 3ff39640859873c8ce1f98886b84f24b1b9124d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer : Maël Kerbiriou <m431.kerbiriou@free.fr>
pkgbase=duckdb-git
pkgname=('duckdb-git' 'python-duckdb-git')
pkgver=v0.1.8.r5.g6978d121b
pkgrel=1
pkgdesc="Embeddable SQL OLAP Database Management System"
arch=('x86_64')
url="https://www.duckdb.org/"
license=('MIT')
makedepends=('git' 'cmake')
checkdepends=('python-pytest')
depends=('gcc-libs')
provides=('duckdb' 'python-duckdb')
source=("${pkgbase}::git+https://github.com/cwida/${pkgbase%-git}.git")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgbase}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cmake -S "${srcdir}/${pkgbase}" -B "${srcdir}/build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr/ \
-DBUILD_TESTING=ON
}
build() {
cd "${srcdir}/build"
make
cd "${srcdir}/${pkgbase}/tools/pythonpkg"
python setup.py build
}
check() {
cd "${srcdir}/${pkgbase}"
"${srcdir}/build/test/unittest"
cd "${srcdir}/${pkgbase}/tools/pythonpkg"
PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.8" pytest
}
package_duckdb-git() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
install -D -m644 "${srcdir}/${pkgbase}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_python-duckdb-git() {
cd "${srcdir}/${pkgbase}/tools/pythonpkg"
python setup.py install --root="${pkgdir}"
install -D -m644 "${srcdir}/${pkgbase}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|