PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Guus van Meerveld <contact@guusvanmeerveld.dev>
pkgbase='dust-mail-client'
pkgname=('dust-mail-client-git')

arch=('x86_64')

pkgver=0.1.4.r2.gef28602
pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
pkgrel=1
epoch=1

makedepends=('yarn' 'nvm' 'cargo' 'git' 'appstream')

url='https://github.com/Guusvanmeerveld/Dust-Mail'

license=('MIT')

source=("$pkgname::git+https://github.com/Guusvanmeerveld/Dust-Mail.git" "dust-mail.desktop" "dust-mail.png")

md5sums=('SKIP' '225f3614b306b30c1bf515ee42c68109' '1c7baa069d5b6aea65b43e37728abbcd')
sha256sums=('SKIP' 'SKIP' 'SKIP')

_ensure_local_nvm() {
    # let's be sure we are starting clean
    which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
    export NVM_DIR="${srcdir}/.nvm"

    # The init script returns 3 if version specified
    # in ./.nvrc is not (yet) installed in $NVM_DIR
    # but nvm itself still gets loaded ok
    source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}

prepare() {
  _ensure_local_nvm
  nvm install 16

  cd "$srcdir/$pkgname/packages/client/src-tauri"

  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  _ensure_local_nvm

  cd "$pkgname/packages/client"

  yarn install --frozen-lockfile

  unset SOURCE_DATE_EPOCH

  export RUSTUP_TOOLCHAIN=1.61

  export VITE_UNSTABLE=true

  yarn run tauri build --verbose
}

package_dust-mail-client-git() {
  pkgdesc='A simple and fast mail client (Git version)'

  conflicts=('dust-mail-client')
  provides=('dust-mail-client')

  install -Dm644 "$srcdir/dust-mail.desktop" "$pkgdir/usr/share/applications/dust-mail-client.desktop"
  install -Dm644 "$srcdir/dust-mail.png" "$pkgdir/usr/share/dust-mail.png"
  install -Dm755 "$srcdir/$pkgname/packages/client/src-tauri/target/release/dust-mail" "$pkgdir/usr/bin/dust-mail-client"
}