summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 51caf511e7cc679078e17d3c111c9e064ff5d217 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Clemmitt Sigler <cmsigler (dot) online (at) gmail (dot) com>

pkgname=dvd-slideshow
pkgver=0.8.6
pkgrel=1
pkgdesc="Scripts for creating slideshow DVDs with menus, audio, and fancy effects."
arch=('any')
url="http://dvd-slideshow.sourceforge.net"
license=('GPL')
depends=('dvdauthor>0.6.11' 'imagemagick>5.5.4' 'sox>14' 'ffmpeg>0.4.8' 'mjpegtools' 'cdrtools' 'bc' 'jhead')
optdepends=('lame: MP3 audio support'
            'vorbis-tools: Ogg audio support'
            'faad2: m4a audio support'
            'vcdimager: vcd/svcd .cue, .bin support'
            'toolame: Faster mpeg2 audio encoding'
            'graphicsmagick: Alternative to imagemagick'
            'libav-no-libs: avconv alternative to ffmpeg'
            'perl-image-exiftool: Alternative to jhead'
            'gsfonts: URW fonts')
install="$pkgname.install"
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver-1.tar.gz"
        "dvd-slideshow_ffprobe.patch"
        "dir2slideshow_exiftool.patch")
sha1sums=('383f4e6ee33e8c344ccc484f61dd868c714b49dd'
          'a96c72392d0dafe19cd93127bfaf70abd1ffa6ed'
          'ae1bf3490fdc78a8e00c0b5c86bdeaaf3cc09a2d')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}-1"
  patch -p1 -i "${srcdir}"/dvd-slideshow_ffprobe.patch
  patch -p1 -i "${srcdir}"/dir2slideshow_exiftool.patch
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}-1"

  for _file in `ls man | sed 's/\.1//'`; do
    install -Dm755 $_file "${pkgdir}/usr/bin/$_file"
    install -Dm644 man/$_file.1 "${pkgdir}/usr/share/man/man1/$_file.1"
    install -Dm644 doc/$_file.html "${pkgdir}/usr/share/doc/$pkgname/$_file.html"
  done

  install -Dm644 "${pkgname}rc" "${pkgdir}/usr/share/$pkgname/${pkgname}rc"
}