summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1a404e4b3fca53978e6894572bbcfb639692ae93 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Dennis W├Âlfing <denniswoelfing at gmx dot de>

pkgname=dxcompress
pkgver=1.1
pkgrel=1
pkgdesc="Compression and decompression utility"
arch=('x86_64')
url="https://github.com/dennis95/dxcompress"
license=('ISC')
depends=('xz' 'zlib')
# The gzip packages provides uncompress and zcat utilities conflicting with the
# dxcompress implementation. Luckily dxcompress can provide gzip
provides=('gzip' 'ncompress')
conflicts=('gzip' 'ncompress')
source=("https://github.com/dennis95/dxcompress/releases/download/dxcompress-$pkgver/dxcompress-$pkgver.tar.xz")
sha256sums=('89c1331a860467a58e0c69e54238fb29c7bdeb436672009efd61964fb6840dc6')

build() {
	cd "dxcompress-$pkgver"
	./configure --prefix=/usr --enable-wrappers=gzip
	make
}

check() {
	cd "dxcompress-$pkgver"
	make check
}

package() {
	cd "dxcompress-$pkgver"
	make DESTDIR="$pkgdir" install
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}