blob: 671185605e3af53f8dc56ca85fd34a11ecdc7b9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Adrià Cereto i Massagué <ssorgatem at gmail.com>
pkgbase=dxvk-wine-git
pkgname=('dxvk-winelib-git')
pkgver=1.1.1.r0.g37f9a7ff
pkgrel=1
pkgdesc="A Vulkan-based compatibility layer for Direct3D 10/11 which allows running 3D applications on Linux using Wine. Winelib version"
arch=('x86_64')
url="https://github.com/doitsujin/dxvk"
license=('zlib/libpng')
depends=('vulkan-icd-loader' 'wine>=4.0rc1' 'lib32-vulkan-icd-loader')
makedepends=('ninja' 'meson>=0.43' 'glslang' 'git' 'wine')
conflicts=("dxvk-bin" "dxvk-git" "dxvk-wine32-git" "dxvk-wine64-git" "dxvk-win32-git" "dxvk-win64-git" "dxvk-mingw-git")
source=("git+https://github.com/doitsujin/dxvk.git" )
sha256sums=("SKIP")
pkgver() {
cd dxvk
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
}
build() {
meson dxvk "build/x64" \
--cross-file dxvk/build-wine64.txt \
--prefix "/usr/share/dxvk/x64" \
--bindir "" --libdir "" \
--buildtype "release" \
--strip \
-D enable_tests=false
ninja -C "build/x64"
meson dxvk "build/x32" \
--cross-file dxvk/build-wine32.txt \
--prefix "/usr/share/dxvk/x32" \
--bindir "" --libdir "" \
--buildtype "release" \
--strip \
-D enable_tests=false
ninja -C "build/x32"
}
package_dxvk-winelib-git() {
DESTDIR="$pkgdir" ninja -C "build/x32" install
DESTDIR="$pkgdir" ninja -C "build/x64" install
install -Dm 644 dxvk/setup_dxvk.sh "$pkgdir/usr/share/dxvk/setup_dxvk.sh"
mkdir -p "$pkgdir/usr/bin"
ln -s /usr/share/dxvk/setup_dxvk.sh "$pkgdir/usr/bin/setup_dxvk"
}
|