PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Aaron DeVore <aaron.devore@gmail.com>
# Co-maintainer: Dan Beste <dan.ray.beste@gmail.com>

pkgname=dybuk-git
gitname=dybuk
pkgver=r37.ef12906
pkgrel=1
pkgdesc='Prettify the ugly Rustc messages'
arch=(
    'i686'
    'x86_64'
)
url='https://github.com/Ticki/dybuk'
license=('MIT')
makedepends=(
    'cargo'
    'git'
    'rust'
)
provides=("${gitname}")
conflicts=("${gitname}")
source=('git+https://github.com/Ticki/dybuk.git')
sha256sums=('SKIP')

pkgver() {
    cd "${gitname}"

    printf "r%s.%s"                     \
        "$(git rev-list --count HEAD)"  \
        "$(git rev-parse --short HEAD)"
}

build() {
    cd "${gitname}"

	cargo build --release
}

package() {
    cd "${gitname}"

    install -m 755 \
        -D target/release/dybuk "${pkgdir}/usr/bin/${gitname}"
    install -m 644 \
        -D LICENSE "${pkgdir}/usr/share/licenses/${gitname}/LICENSE"
}