summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 33e708a3a700a0a9d840be04f5da90082447fd67 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
# Maintainer: Yaroslav Krytsun <slavko7 at gmail dot com>
pkgname=dyedfox-radio
pkgver=0.8.3
pkgrel=1
pkgdesc="Desktop internet radio player"
arch=('any')
url="https://github.com/dyedfox/dyedfox-radio"
license=('GPL-3.0-or-later')
depends=(
    'python'
    'python-pyqt6'
    'python-requests'
    'python-dbus'
    'python-gobject'
    'gstreamer'
    'gst-plugins-base'
    'gst-plugins-good'
)
optdepends=(
    'gst-plugins-bad: additional codec support'
    'gst-libav: AAC and other codec support'
)
makedepends=('git' 'qt6-tools')
source=("$pkgname-$pkgver::git+${url}.git#tag=v${pkgver}")
sha256sums=('SKIP')

build() {
    cd "$srcdir/$pkgname-$pkgver"
    for ts in translations/*.ts; do
        lrelease6 "$ts"
    done
}

package() {
    cd "$srcdir/$pkgname-$pkgver"

    install -dm755 "$pkgdir/usr/lib/$pkgname"
    cp -r api data player tray ui assets main.py "$pkgdir/usr/lib/$pkgname/"

    install -dm755 "$pkgdir/usr/lib/$pkgname/translations"
    for qm in translations/*.qm; do
        [ -f "$qm" ] && install -m644 "$qm" "$pkgdir/usr/lib/$pkgname/translations/"
    done

    install -Dm644 "assets/icons/$pkgname.png" \
        "$pkgdir/usr/share/icons/hicolor/256x256/apps/$pkgname.png"
    install -Dm644 "assets/icons/$pkgname-tray.svg" \
        "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname-tray.svg"
    install -Dm644 "assets/icons/$pkgname-symbolic.svg" \
        "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname-symbolic.svg"

    install -Dm644 "$pkgname.desktop" \
        "$pkgdir/usr/share/applications/$pkgname.desktop"

    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    install -dm755 "$pkgdir/usr/bin"
    cat > "$pkgdir/usr/bin/$pkgname" << 'LAUNCHER'
#!/bin/sh
exec python3 /usr/lib/dyedfox-radio/main.py "$@"
LAUNCHER
    chmod 755 "$pkgdir/usr/bin/$pkgname"
}