blob: fcc63ce7b8e26ef63cb25fbb3dc67968bfd38c7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
_pkgname=dynarmic
pkgname=$_pkgname-git
pkgver=5.r113.g517e35f8
pkgrel=1
pkgdesc='An ARM dynamic recompiler'
arch=('x86_64')
url="https://github.com/MerryMage/$_pkgname"
license=('BSD')
makedepends=(
'boost>=1.57'
'cmake>=3.8'
'fmt>=8'
'git'
'robin-map>=0.6.2'
'xbyak>=5.995.r3'
'zydis>=3.1'
)
checkdepends=('catch2>=2.13.1')
provides=("$_pkgname=$pkgver" 'libdynarmic.so')
conflicts=("$_pkgname")
source=(
"git+$url.git"
"0002-dynarmic-add-cmake-install-rules.patch::$url/pull/636.patch"
'unbundle-catch2.patch'
'unbundle-fmt.patch'
'unbundle-robin-map.patch'
'unbundle-xbyak.patch'
'unbundle-zydis.patch'
)
b2sums=(
'SKIP'
'bb8bfeccd4a944a36df33ce77bc15a8680bd06c80aeabac17ff052fc651468f559625ca0b1db52bd3badd228270f0e5dd0958d65710f8f3be67ed91be7464948'
'd5adb75e25b1f3cb297f781d4c00d978d234912ca7fcb4e206e7f7779ccbe9a9d747c652a6fc2d8af55442b457dc8d496f3708b67fa0072aba8cdf5aba15bdde'
'4bcf176ce2a82cbaf54f9eb0b463844e77c099e5824fb9d994817dd8a5b75ea1abebf17da4c01be14042ce36564d8df5836e9a02a5cbe92bb95d7232263123b4'
'd474ec20f085832c73de96b19a06b5d8018d6fb429ea054a9e026c1d56f12035b83bc3b980487825ecb473b674a7b22f2b92733bdb53d71dcb1528318f2a5d80'
'92d760e22bebe7d07bee8fdcc4d142ae8bc11e73c1d6e89e3964d07a1618c3ad4516eeaa262b6f7046a8b483c4b56d2e509b170fe9acf48eea7523210c0e9fa7'
'1e6ff855e427df6c7f618c9507af5a267b26da54c9f154daa000c1da2797b963a3604a7a9e6d7b32395fc9084b5c49f425814ae169e45d4c4b08f3f34d1cf597'
)
pkgver() {
cd $_pkgname
git describe --long --tags | sed 's/^r//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $_pkgname
patch -Np1 < ../0002-dynarmic-add-cmake-install-rules.patch
patch -Np1 < ../unbundle-catch2.patch
patch -Np1 < ../unbundle-fmt.patch
patch -Np1 < ../unbundle-robin-map.patch
patch -Np1 < ../unbundle-xbyak.patch
patch -Np1 < ../unbundle-zydis.patch
}
build() {
cmake -S $_pkgname -B build \
-DBUILD_SHARED_LIBS=ON \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DDYNARMIC_IGNORE_ASSERTS=ON \
-DDYNARMIC_NO_BUNDLED_FMT=ON \
-DDYNARMIC_TESTS="$CHECKFUNC" \
-Wno-dev
cmake --build build
}
check() {
cmake --build build --target test
}
package() {
depends+=('libfmt.so' 'libZydis.so')
# shellcheck disable=SC2154
DESTDIR="$pkgdir" cmake --install build
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname $_pkgname/LICENSE.txt
}
|