PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Hans-Nikolai Viessmann <hans AT viess DOT mn>
_pkg='easybuild-framework'
pkgname="${_pkg}-git"
pkgver=4.8.2.r41.ga2eaf2365
pkgrel=2
pkgdesc="A software build and installation framework for HPC systems (development)"
arch=('any')
url="https://github.com/easybuilders"
license=('GPL2')
depends=('python' 'env-modules' 'python-setuptools' 'python-distro'
         'python-yaml' 'python-configobj' 'python-packaging'
         'python-humanfriendly' 'python-requests')
optdepends=('lmod: another module management tool'
            'fpm: Generate packages of your modules to be installed later'
            'easybuild-easyconfigs: collection of build parameters'
            'easybuild-easyblocks: collection of module recipes'
            'python-gitpython: for using Git with EasyBuild'
            'graphviz: for building nice looking dependency graphs'
            'python-keyring: for handling authentication with GitHub'
            'python-rich: lets EasyBuild show rich-output, i.e. nice progress bars')
makedepends=('git')
provides=("${_pkg}")
conflicts=("${_pkg}")
source=("git+https://github.com/easybuilders/${_pkg}.git#branch=develop")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$_pkg"
    printf "%s" "$(git describe --long | sed 's/\([^-]*-g\)/r\1/;s/.*v\(.*\)$/\1/;s/-/./g')"
}

prepare() {
    git -C "$srcdir/$_pkg" clean -dfx
}

build() {
    cd "$srcdir/$_pkg"
    python setup.py build
}

package() {
    cd "$srcdir/$_pkg"
    python setup.py install --root="$pkgdir" --optimize=1
}