blob: 877e25ac3cbf586e20e98813ce67e505b292e691 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: robertfoster
# Contributor: Bleuzen <supgesu@gmail.com>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Wellington <wellingtonwallace@gmail.com>
pkgname=easyeffects-git
pkgver=8.0.0.r0.g2a3986ca4
pkgrel=1
pkgdesc='Audio Effects for PipeWire applications'
arch=(x86_64 i686 arm armv6h armv7h aarch64)
url='https://github.com/wwmm/easyeffects'
license=('GPL-3.0-only')
depends=(
'breeze-icons'
'gsl'
'kconfigwidgets'
'kiconthemes'
'kirigami'
'kirigami-addons'
'libbs2b'
'libebur128'
'libmysofa'
'libsndfile'
'lilv'
'nlohmann-json'
'pipewire-pulse'
'qqc2-desktop-style'
'qt6-base'
'qt6-graphs'
'rnnoise'
'soundtouch'
'speexdsp'
'tbb'
'webrtc-audio-processing'
'zita-convolver'
)
makedepends=('appstream' 'cmake' 'extra-cmake-modules' 'git' 'intltool' 'ladspa' 'ninja')
optdepends=(
'breeze: KDE breeze style'
'calf: exciter, bass enhancer and others'
'lsp-plugins-lv2: limiter, equalizer, compressor, loudness and others'
'zam-plugins-lv2: maximizer'
'mda.lv2: bass loudness'
'x42-plugins-lv2: autotune'
'libdeep_filter_ladspa: deep noise remover'
)
conflicts=("${pkgname%%-git}")
provides=("${pkgname%%-git}")
source=("${pkgname%%-git}::git+${url}")
sha512sums=('SKIP')
pkgver() {
cd "${pkgname%%-git}"
printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
}
build() {
local cmake_options=(
-B build
-S "${pkgname%%-git}"
-W no-dev
-D CMAKE_BUILD_TYPE=None
-D CMAKE_INSTALL_PREFIX=/usr
-G Ninja
)
cmake "${cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
}
|