blob: 050ee47321b0aed6f0aa70fc0c67347b115a19d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Raymond Li <aur@raymond.li>
# Co-maintainer: Steve Finkel <mrsteve0924@verizon.net>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Kevin Sullivan <ksullivan@archlinux.us>
# Contributor Krystian Duzynski <https://github.com/KrystianD>
pkgname=easystroke
pkgver=0.6.0
pkgrel=24
pkgdesc='Use mouse gestures to initiate commands and hotkeys'
arch=('x86_64')
url='https://github.com/mrsteve0924/easystroke'
license=('custom:ISC')
depends=('gtkmm3' 'boost-libs' 'libxtst' 'dbus-glib' 'xorg-server')
makedepends=('boost' 'xorgproto' 'intltool' 'gettext' 'xorg-server-devel' 'help2man')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/mrsteve0924/${pkgname}/archive/v${pkgver}.tar.gz")
sha256sums=('c5851abd8b1b77d494eff108b2c0e2cc8cf689800bcfb2eead9f5e68274b37f9')
prepare() {
cd "${pkgname}-${pkgver}"
sed -E 's&-Wall&-Wno-error=incompatible-pointer-types&g' -i Makefile
}
build() {
cd "${pkgname}-${pkgver}"
make
make man
}
package() {
cd "${pkgname}-${pkgver}"
make PREFIX=/usr DESTDIR="${pkgdir}" install
install -Dm0644 "${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|