blob: f32558e1d336ca72a547fd2683fd0518a7be08b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
# Maintainer: Carson Black <uhhadd@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Paul Mattal <paul@archlinux.org>
# Contributor: Andrew Wright <andreww@photism.org>
# Contributor: Andreas W. Hauser <andy-aur@splashground.de>
# Contributor: Marco Crosio <marco.crosio@gmail.com>
pkgbase=eclipse
pkgname=(eclipse-{common,java,jee,cpp,php,javascript,rust})
pkgver=4.15
pkgrel=6
_release=2020-03/R
pkgdesc="Highly extensible IDE"
license=(EPL)
arch=(x86_64)
url="https://eclipse.org"
makedepends=(python3)
source=(commonify)
sha256sums=('a68cccdf182449dfb4aef595ab26fe6542902421aef42a79672483865cbbd0ea')
sha256sums_x86_64=('72fde94154999df569cbd30551bc784341391b9753209cd563829a6c8674383e' # Java
'1f6b44cc8a8665f452170f395523486e3555570174768d96d8ca7e2bacc3f31d' # Jee
'3cc546c7bd9214ca834cf5d8bcd16e300ae0fa95f1bf49e15c52ea47235b7f01' # C++
'0d6662d7a57585320f441029358261c23e570bf7779cbe34ee2f91208b2aff54' # PHP
'25a2e502e33c0a4b6629b35dfb140d5bd772d932ca472e554f672524d189caec' # JS
'c52860b6134e083aa263d1c1eb80f4a904cdf284d25f7aaee472950386347109') # Rust
_sourcename() {
case $1 in
eclipse-common) return 1 ;;
eclipse-rust|eclipse-cpp|eclipse-jee|eclipse-javascript) echo $1-${_release//\//-}-incubation-linux-gtk-x86_64.tar.gz ;;
* ) echo $1-${_release//\//-}-linux-gtk-x86_64.tar.gz ;;
esac
}
source_x86_64=()
noextract=()
for _pkg in ${pkgname[@]}; do
_src=$(_sourcename $_pkg) || continue
source_x86_64+=(http://ftp-stud.fht-esslingen.de/pub/Mirrors/eclipse/technology/epp/downloads/release/$_release/$_src)
noextract+=($_src)
eval "package_$_pkg() { _package $_pkg; }"
done
prepare() {
local pkg src
for pkg in ${pkgname[@]}; do
mkdir $pkg
src=$(_sourcename $pkg) || continue
bsdtar -xf $src -C $pkg --strip-components 1
done
}
build() {
mkdir eclipse-common/dropins
touch eclipse-common/dropins/.keep
./commonify --identical ${pkgname[@]}
}
package_eclipse-common() {
pkgdesc+=" (common files)"
depends=("java-environment>=8" webkit2gtk unzip)
install -d "$pkgdir/usr/lib"
cp -a eclipse-common "$pkgdir/usr/lib/eclipse"
}
_package() {
local variant i
case ${1#eclipse-} in
java ) variant=Java; replaces=(eclipse) ;;
jee ) variant=JEE ;;
cpp ) variant=C++; replaces=(eclipse-cdt) ;;
php ) variant=PHP ;;
javascript) variant=JavaScript ;;
rust ) variant=Rust ;;
* ) return 1 ;;
esac
pkgdesc+=" for $variant"
depends=("eclipse-common=$pkgver-$pkgrel" bash)
provides=("eclipse=$pkgver-$pkgrel")
conflicts=(eclipse)
install -d "$pkgdir/usr/lib"
cp -a $1 "$pkgdir/usr/lib/eclipse"
install -D /dev/stdin "$pkgdir/usr/bin/eclipse" <<END
#!/bin/bash
export ECLIPSE_HOME=/usr/lib/eclipse
exec \$ECLIPSE_HOME/eclipse "\$@"
END
install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/eclipse.desktop" <<END
[Desktop Entry]
Name=Eclipse
Comment=$variant Development Environment
Icon=eclipse
Exec=eclipse
Terminal=false
Type=Application
Categories=Development;IDE;Java;
StartupNotify=true
END
for i in 16 22 24 32 48 64 128 256 512 1024; do
install -Dm644 eclipse-common/plugins/org.eclipse.platform_*/eclipse$i.png \
"$pkgdir/usr/share/icons/hicolor/${i}x$i/apps/eclipse.png"
done
}
|