blob: d6e5c073d6c9343379e5f60fe70d6e0f61e7439b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Mattia Moffa <mattia [at] moffa [dot] xyz>
pkgname=eclipse-jee-bin
_pkgname=${pkgname%-bin}
epoch=2
pkgver=4.40
pkgrel=1
_release=2026-06/R
pkgdesc="Highly extensible IDE (Enterprise Java and Web version)"
arch=('x86_64' 'aarch64')
url="https://www.eclipse.org/"
license=('EPL')
depends=('java-runtime>=21' webkit2gtk-4.1 unzip)
makedepends=()
provides=(eclipse=$pkgver-$pkgrel)
conflicts=(eclipse)
options=(!strip)
_srcfilename_x86_64="$_pkgname-${_release//\//-}-linux-gtk-x86_64.tar.gz"
_srcfilename_aarch64="$_pkgname-${_release//\//-}-linux-gtk-aarch64.tar.gz"
source_x86_64=("$_srcfilename_x86_64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_x86_64&r=1")
source_aarch64=("$_srcfilename_aarch64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_aarch64&r=1")
sha512sums=('9da29da1fe9e4ac4b8f1a4faef158155399574752a317addf90f6a068019ad62906f8ce1db11e543c7fee7dbf3dd8273aa34fc86ff2354420371cdf9b017cdf3')
sha512sums_x86_64=('65457ef8d0d7bf17b40bbd9cc954b6ede7a4eb8983c9cfda842c31493402762f19a3ff8004a45180d5f74e78527639a88084c222384c4c20d3ae5aeb5d5934be')
sha512sums_aarch64=('4f2c144444d1717c7b2b67fddc9a006236432337595833424527f551e0bfe35ef347500597b2ed9a8c37300100c26042317572e6424b099f993192c9c7affdf2')
source=("eclipse.desktop")
#backup=('usr/lib/eclipse/eclipse.ini')
package() {
install -d "${pkgdir}/usr/lib"
cp -r "eclipse" "${pkgdir}/usr/lib/eclipse"
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/eclipse/eclipse" "${pkgdir}/usr/bin/eclipse"
install -Dm644 "eclipse.desktop" "${pkgdir}/usr/share/applications/eclipse.desktop"
for i in 16 22 24 32 48 64 128 256 512 1024 ; do
install -Dm644 eclipse/plugins/org.eclipse.platform_${pkgver}*/eclipse$i.png \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/eclipse.png"
done
}
|