blob: 2ce7a3b3ff79cdff861ebef9a2007d340b59738e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Former Maintainer: Julien Nicoulaud <julien.nicoulaud@gmail.com>
# Current Maintainer: Ning Sun <sunng@about.me>
pkgname=eclipse-mat
_pgname=MemoryAnalyzer
_pkgver=1.7
pkgver=1.7.0
_releasedate=20170613
pkgrel=1
pkgdesc="Eclipse Memory Analyzer Tool (MAT), a toolkit for analyzing Java heap dumps."
arch=(i686 x86_64)
url="http://www.eclipse.org/mat"
license=(EPL)
depends=('java-runtime>=6' 'gtk2')
install=${pkgname}.install
sha512sums_i686=('acded7eb97295af37ae424fe70b2014e12f046d8fca864beec4a4fe3e35af8163a90fd1d35736737a1da0c7b4599ae92cef5648d75c0edacaab9a3f76aeccaf5')
sha512sums_x86_64=('b95716e553b0b502dad099462aaa3e2e980995f164c34e073f1048f041e312a79250a21e2f5239e00eaafa5891247927ffc4017fd8000c3a2624e36c4dee3e49')
source_i686=("${pkgname}-${pkgver}-x86.zip::http://download.eclipse.org/mat/${_pkgver}/rcp/${_pgname}-${pkgver}.${_releasedate}-linux.gtk.x86.zip")
source_x86_64=("${pkgname}-${pkgver}-x86_64.zip::http://download.eclipse.org/mat/${_pkgver}/rcp/${_pgname}-${pkgver}.${_releasedate}-linux.gtk.x86_64.zip")
build() {
msg2 "Generate desktop application entry..."
cat > "${srcdir}"/${pkgname}.desktop << EOF
[Desktop Entry]
Version=${pkgver}
Encoding=UTF-8
Name=Eclipse MAT
Comment=${pkgdesc}
Exec=/usr/bin/${pkgname}
Terminal=false
Type=Application
Categories=Development;
EOF
}
package() {
msg2 "Install the assembly at /opt/${pkgname}..."
install -dm755 "${pkgdir}"/opt/${pkgname}
cp -a "${srcdir}"/mat/* "${pkgdir}"/opt/${pkgname}
msg2 "Install link to the executable in /usr/bin..."
install -dm755 "${pkgdir}"/usr/bin
ln -s /opt/${pkgname}/${_pgname} "${pkgdir}"/usr/bin/${pkgname}
msg2 "Install link to the config file in /etc..."
install -dm755 "${pkgdir}"/etc
ln -s /opt/${pkgname}/${_pgname}.ini "${pkgdir}"/etc/${pkgname}.ini
msg2 "Install links to copyright resources at /usr/share/licenses/${pkgname}..."
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s /opt/${pkgname}/epl-v10.html "${pkgdir}/usr/share/licenses/${pkgname}/"
ln -s /opt/${pkgname}/notice.html "${pkgdir}/usr/share/licenses/${pkgname}/"
msg2 "Install desktop application entry in /usr/share/applications..."
install -Dm644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}
|