blob: cbcf7882123f3fd2cb6c14b53fb6fa45c3db66ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
_pkgname=edex-ui
pkgname=${_pkgname}-bin
pkgver=2.2.5
pkgrel=1
pkgdesc='A cross-platform, customizable science fiction terminal emulator with advanced monitoring & touchscreen support'
url='https://github.com/GitSquared/edex-ui'
license=('GPL3')
arch=('i686' 'x86_64' 'aarch64')
depends=('gtk3' 'libxss' 'nss')
provides=('edex-ui')
conflicts=('edex-ui')
source=("LICENSE::https://raw.githubusercontent.com/GitSquared/edex-ui/v${pkgver}/LICENSE")
source_i686=("${pkgname}-${pkgver}.i686.AppImage::https://github.com/GitSquared/edex-ui/releases/download/v${pkgver}/eDEX-UI-Linux-i386.AppImage")
source_x86_64=("${pkgname}-${pkgver}.x86_64.AppImage::https://github.com/GitSquared/edex-ui/releases/download/v${pkgver}/eDEX-UI-Linux-x86_64.AppImage")
source_aarch64=("${pkgname}-${pkgver}.aarch64.AppImage::https://github.com/GitSquared/edex-ui/releases/download/v${pkgver}/eDEX-UI-Linux-arm64.AppImage")
noextract=("${pkgname}-${pkgver}.${CARCH}.AppImage")
options=(!strip)
sha256sums=('589ed823e9a84c56feb95ac58e7cf384626b9cbf4fda2a907bc36e103de1bad2')
sha256sums_i686=('c1634e6f30576c8fe7b58809145ca7118635d5905c6fb94da64efc7043c81612')
sha256sums_x86_64=('ba81dd376bd214df03e8db3ad4d2953e6b8e290834f908ac1e4638c808d86153')
sha256sums_aarch64=('1068261a5e09173f78ea4f827b32c530a284baecd2a95aa3436c812e8c496fe2')
b2sums=('399283bc59e70998486f2ae7b0af9f2f241206dd660e50808be3cef500adef2a9e8d449304f506d93bd2281e6b0729b16145173591deeb105ef545b769453e10')
b2sums_i686=('ecbb04b32592fc7378d23c162841eed2514a2ee959492b484d5c16e3d976dcbdfd896046b7bbe31c991e293fed636628cd5aaedd0509a864a988047a3b198360')
b2sums_x86_64=('67782ba1f3a31ddfb46cbdf4c1bb73ad158bb0f28c1a30a413ac4fb6c412e5e39ac69f0f84489cafa2961ec09895a7ba6574b06f5b2e86e9576e085d2398661a')
b2sums_aarch64=('af78c3db2b1dce2676e441453f16f8f88ec64533836b940b1a75d5febf049a7edd722da96013738130519c10dbb63995113b0ac813989f70565530be0f6a6f3e')
prepare() {
chmod +x "${pkgname}-${pkgver}.${CARCH}.AppImage"
"./${pkgname}-${pkgver}.${CARCH}.AppImage" --appimage-extract
}
build() {
sed -i -E "s|Exec=AppRun|Exec=/usr/bin/${_pkgname}|" "squashfs-root/${_pkgname}.desktop"
}
package() {
# Copy app files
install -dm0755 "${pkgdir}/opt/${_pkgname}"
cp -a squashfs-root/* "${pkgdir}/opt/${_pkgname}"
# Remove unused files
rm -rf "${pkgdir}/opt/${_pkgname}"/{usr,swiftshader,AppRun,${_pkgname}.{desktop,png}}
# Fix permissions
for d in locales resources; do
chmod 0755 "${pkgdir}/opt/${_pkgname}/$d"
find "${pkgdir}/opt/${_pkgname}/$d" -type d -exec chmod 0755 {} +
done
# Link entry point
install -dm0755 "${pkgdir}/usr/bin"
ln -sf "/opt/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
# Copy icons files
install -dm0755 "${pkgdir}/usr/share/icons"
find squashfs-root/usr/share/icons -type d -exec chmod 0755 {} +
cp -a squashfs-root/usr/share/icons/* "${pkgdir}/usr/share/icons"
# Copy desktop file
install -Dm0644 "squashfs-root/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
# Install LICENSE file
install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|