blob: 8bafe29fc4248223b91bf5a4295a167cd58d04d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=editide
_app_id="io.frama.$pkgname.$pkgname"
pkgver=4.0.5
pkgrel=1
pkgdesc="Source-code editor with basic project support"
arch=('x86_64')
url="https://editide.frama.io"
license=('CC0-1.0 AND CC-BY-SA-3.0 AND LGPL-2.1-or-later')
depends=(
'gtk4'
'gtksourceview5'
'python-gobject'
)
makedepends=(
'desktop-file-utils'
'git'
'meson'
'setconf'
)
checkdepends=('appstream')
optdepends=(
'ctags: For symbols'
'git: For the git extension'
'libadwaita: For the Adwaita theme and recoloring'
'libspelling: For the spellchecking extension'
)
source=("git+https://framagit.org/editide/releases.git#tag=$pkgver"
'git+https://framagit.org/editide/editide.git')
sha256sums=('2d65f7743d83194cc353ab9081661bf5d27d5d1ec3b8316cdef26409f40cdd8b'
'SKIP')
prepare() {
cd releases
setconf .gitmodules url https://framagit.org/editide/editide.git
git submodule init
git config "submodule.src/$pkgname.url" "$srcdir/$pkgname"
git -c protocol.file.allow=always submodule update
}
build() {
arch-meson releases build
meson compile -C build
desktop-file-edit --set-key=Exec --set-value="$pkgname" \
--set-key=StartupWMClass --set-value=localhost.EdiTidE4 \
"build/data/${_app_id}.desktop"
}
check() {
meson test -C build --no-rebuild --print-errorlogs
}
package() {
meson install -C build --no-rebuild --destdir "$pkgdir"
}
|