PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer: David Cohen <dacohen@pm.me>

pkgname=efistub-libre
pkgver=260.1
pkgrel=3
pkgdesc="Systemd's EFI stubs collections without systemd"
arch=('x86_64')
url="https://github.com/systemd/systemd"
license=('LGPL2.1')
makedepends=(
    'clang'
    'git'
    'gperf'
    'lld'
    'meson'
    'ninja'
    'python'
    'python-jinja'
    'python-pyelftools'
)
provides=('systemd-efi-stub')
conflicts=('systemd-efi-stub')

source=("git+https://github.com/systemd/systemd.git?shallow=1#tag=v${pkgver}")
sha256sums=('SKIP')

build() {
    cd "systemd"

    meson setup build \
        -Defi=true \
        -Dstandalone-binaries=true \
        -Dnss-myhostname=false \
        -Dnss-mymachines=disabled \
        -Dnss-resolve=disabled \
        -Dnss-systemd=false \
        -Dman=disabled \
        -Dhtml=disabled \
        -Dtests=false \
        -Daudit=disabled \
        -Dblkid=disabled \
        -Dkmod=disabled \
        -Dlibcryptsetup=disabled \
        -Dlibcurl=disabled \
        -Dp11kit=disabled \
        -Dpam=disabled \
        -Dmicrohttpd=disabled \
        -Dselinux=disabled \
        -Dxkbcommon=disabled \
        -Dzstd=disabled

    ninja -C build src/boot/linuxx64.efi.stub src/boot/addonx64.elf.stub
}

package() {
    cd "systemd"

    # Install all available EFI stub architectures to /usr/lib/boot/efi/
    for stub in build/src/boot/linux*.efi.stub build/src/boot/addon*.elf.stub; do
        if [ -f "$stub" ]; then
            local stubname=$(basename "$stub")
            install -Dm755 "$stub" "${pkgdir}/usr/lib/boot/efi/${stubname}"
        fi
    done

    install="${pkgbase}.install"
}