blob: cec187c17f2c4c063331cfe2cc47e61e243e22ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Ronald van Haren <ronald.archlinux.org>
_pkgname=efl
pkgname=$_pkgname-git
pkgver=1.10.99.25802.b8ca758
pkgrel=1
pkgdesc="Enlightenment Foundation Libraries - Development version"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('BSD' 'LGPL2.1' 'GPL2' 'custom')
depends=('avahi' 'bullet' 'curl' 'fontconfig' 'fribidi' 'gst-plugins-base-libs' 'luajit' 'libexif'
'libgl' 'libpulse' 'libwebp' 'libxcomposite' 'libxcursor' 'libxinerama' 'libxkbcommon'
'libxp' 'libxrandr' 'libxss' 'shared-mime-info' 'wayland')
[[ ! $(pacman -T "openjpeg") ]] && depends+=('openjpeg') #jpeg2k loader is autodetected at build time
makedepends=('git' 'python2')
optdepends=('python2: compare Eina benchmarks'
'gst-plugins-base: Access more types of video in Emotion'
'gst-plugins-good: Access more types of video in Emotion'
'gst-plugins-bad: Access more types of video in Emotion'
'gst-plugins-ugly: Access more types of video in Emotion'
'gst-libav: Access video with ffmpeg/libav in Emotion'
'evas_generic_loaders-git: More video/graphic/icon loaders for Evas')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
options=('debug')
install="$_pkgname.install"
source=("git://git.enlightenment.org/core/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
local efl_version=$(grep -m1 EFL_VERSION configure.ac | awk -F [][] '{print $2 "." $4 "." $6}')
efl_version=$(awk -F , -v efl_version=${efl_version%.} '/^AC_INIT/ {gsub(/efl_version/, efl_version); gsub(/[\[\] -]/, ""); print $2}' configure.ac)
printf "$efl_version.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/$_pkgname"
export CFLAGS="$CFLAGS -fvisibility=hidden"
export CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
./autogen.sh \
--prefix=/usr \
--with-tests=none \
--with-opengl=full \
--disable-egl \
--enable-wayland \
--enable-drm \
--enable-fb \
--disable-tslib \
--enable-image-loader-webp \
--enable-systemd \
--enable-harfbuzz \
--enable-xinput22 \
--enable-multisense
make
}
package() {
cd "$srcdir/$_pkgname"
make -j1 DESTDIR="$pkgdir" install
# install text files
install -d "$pkgdir/usr/share/doc/$_pkgname"
install -m644 -t "$pkgdir/usr/share/doc/$_pkgname/" ChangeLog NEWS README
# install license files
install -d "$pkgdir/usr/share/licenses/$pkgname/"
install -m644 -t "$pkgdir/usr/share/licenses/$pkgname/" AUTHORS COMPLIANCE COPYING licenses/COPYING.{BSD,SMALL}
sed -n '1,/details./p' licenses/COPYING.LGPL > "$pkgdir/usr/share/licenses/$pkgname/COPYING.LGPL"
ln -s ../common/GPL2/license.txt "$pkgdir/usr/share/licenses/$pkgname/COPYING.GPL"
python2 -m compileall -q "$pkgdir"
}
|