blob: 6ef8f95c2e1228f071b4a25c42b6ce70ebe23937 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Gavin Fernandes <gavinfernandes2012@gmail.com>
# Contributor: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Ronald van Haren <ronald.archlinux.org>
_pkgname=efl
pkgname=$_pkgname-git
pkgver=1.18.0beta1.49353.g4352747
pkgrel=1
pkgdesc="Enlightenment Foundation Libraries - Development version"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('BSD' 'LGPL2.1' 'GPL2' 'custom')
depends=('avahi' 'bullet' 'curl' 'fontconfig' 'fribidi' 'gst-plugins-base-libs' 'wayland-protocols' 'luajit' 'libexif'
'libgl' 'libinput' 'libpulse' 'libspectre' 'libraw' 'librsvg' 'libwebp' 'libxcomposite'
'libxcursor' 'libxinerama' 'libxkbcommon' 'libxp' 'libxrandr' 'libxss' 'libunwind'
'mesa' 'openjpeg' 'poppler' 'wayland')
makedepends=('git' 'python2')
optdepends=('geoclue: For elocation'
'gst-plugins-base: Video and thumbnail codecs'
'gst-plugins-good: Video and thumbnail codecs'
'gst-plugins-bad: Video and thumbnail codecs'
'gst-plugins-ugly: Video and thumbnail codecs'
'gst-libav: Video and thumbnails with ffmpeg/libav'
'libreoffice: Office document thumbnails'
'python2: Compare Eina benchmarks')
provides=("$_pkgname=$pkgver" elementary{,-git}=$pkgver "evas_generic_loaders=$pkgver")
conflicts=("$_pkgname" elementary{,-git} elementary_test{,-git} evas_generic_loaders{,-git})
options=('debug')
source=("git://git.enlightenment.org/core/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
local efl_version=$(grep -m1 EFL_VERSION configure.ac | awk -F [][] '{print $2 "." $4 "." $6}')
efl_version=$efl_version$(awk 'match($0, /^AC_INIT\(.*\[efl_version-?([^\]]*)\]/, a) {print a[1]}' configure.ac)
printf "%s.%s.g%s" "$efl_version" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd $_pkgname
export CFLAGS="$CFLAGS -fvisibility=hidden"
export CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
./autogen.sh \
--prefix=/usr \
--with-tests=none \
--with-opengl=full \
--disable-egl \
--enable-wayland \
--enable-drm \
--enable-elput \
--enable-fb \
--disable-tslib \
--enable-image-loader-webp \
--enable-systemd \
--enable-harfbuzz \
--enable-xinput22 \
--enable-multisense \
--enable-liblz4
make
}
package() {
cd $_pkgname
make -j1 DESTDIR="$pkgdir" install
# compile python files
python2 -m compileall -q "$pkgdir"
python2 -O -m compileall -q "$pkgdir"
install -Dm644 -t "$pkgdir/usr/share/doc/$_pkgname/" ChangeLog NEWS README
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" AUTHORS COMPLIANCE COPYING COPYING.images licenses/COPYING.{BSD,SMALL}
}
|