blob: 4593a0d089300dd5165d33c22bb32a6f31d3d595 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: heavysink <winstonwu91@gmail.com>
_pkgname=eka2l1
pkgname="${_pkgname}-git"
pkgver=5852.e67f84dc6
pkgrel=4
pkgdesc="Experimental Symbian OS emulator (GIT version)"
arch=('x86_64')
url="https://github.com/EKA2L1/EKA2L1"
license=('GPL2')
makedepends=(
'boost'
'git'
'ccache'
'glfw'
'vulkan-headers'
'python'
'qt6-tools'
'qt6-declarative'
'imagemagick'
'clang'
'cmake3-bin'
)
depends=(
'qt6-base'
'qt6-svg'
'sdl2'
'vulkan-icd-loader'
)
install="eka2l1-git.install"
provides=('eka2l1')
conflicts=('eka2l1')
options=('!lto')
source=(
"${_pkgname}-git::git+https://github.com/EKA2L1/EKA2L1.git"
"eka2l1_qt"
)
md5sums=('SKIP'
'904f15dfd859ab3c10d7f1b9a78db41d')
pkgver() {
cd "${_pkgname}-git"
printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}-git"
git submodule update --recursive --init
sed -i 's/-Werror//g' src/external/mbedtls/CMakeLists.txt
sed -i '/#include <cstdint>/a #include <algorithm>' src/emu/common/include/common/pystr.h
}
build() {
cd "${srcdir}/${_pkgname}-git"
export CFLAGS+=" -Wno-incompatible-pointer-types -Wno-int-conversion"
cmake3 -B build -DCMAKE_BUILD_TYPE=Release -DEKA2L1_NO_TERMINAL=ON -DEKA2L1_ENABLE_UNEXPECTED_EXCEPTION_HANDLER=ON -DEKA2L1_BUILD_VULKAN_BACKEND=OFF -DEKA2L1_BUILD_TESTS=OFF -DCMAKE_INSTALL_PREFIX=/opt/eka2l1 -DCMAKE_POLICY_VERSION_MINIMUM=3.5 .
cd build
make
}
package() {
cd "${srcdir}/${_pkgname}-git/build"
install -d -m 755 "${pkgdir}/opt"
install -d -m 777 "${pkgdir}/opt/eka2l1"
install -d -m 755 "${pkgdir}/usr/bin"
cp -R "${srcdir}/${_pkgname}-git/build/bin/." "${pkgdir}/opt/eka2l1"
install -m 755 ${srcdir}/eka2l1_qt "${pkgdir}/usr/bin/eka2l1_qt"
for s in 16 24 32 48 64 96 128 512; do
install -d -m 755 "${pkgdir}/usr/share/icons/hicolor/${s}x${s}/apps"
convert "${srcdir}/${_pkgname}-git/src/emu/qt/duck_tank.ico" -resize ${s}x${s} "${pkgdir}/usr/share/icons/hicolor/${s}x${s}/apps/duck_tank.png"
done
install -d -m 755 "${pkgdir}/usr/share/applications"
install -m 644 "${srcdir}/${_pkgname}-git/src/emu/qt/eka2l1.desktop" "${pkgdir}/usr/share/applications/eka2l1.desktop"
}
|