blob: 06f525aaf01574ceb8e8c9e59ff3816234b840d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer:
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Mateusz Herych <heniekk@gmail.com>
pkgname=ekg2
pkgver=0.3.1+5820+gf427d083
_pkgver=0.3.1
pkgrel=1
pkgdesc='Ncurses based Jabber, Gadu-Gadu, Tlen and IRC client'
arch=('x86_64')
url='https://github.com/ekg2/ekg2'
license=('GPL')
depends=('aspell' 'gpgme' 'gpm' 'libgadu' 'python2')
makedepends=('git')
_commit=f427d083ee899d42532c046100490a915b0e8a82 # master
source=("git+https://github.com/ekg2/ekg2#commit=$_commit")
md5sums=('SKIP')
pkgver() {
cd $pkgname
printf "$_pkgver+%s+g%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $pkgname
sed -i 's@^#!.*python$@#!/usr/bin/python2@' contrib/python/notify-bubble.py
}
build() {
cd $pkgname
./autogen.sh --prefix=/usr PYTHON=python2
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
rm -r "$pkgdir"/usr/lib/perl5/5.*/core_perl
}
|