blob: 782dedef5f9de30a5b6c26104a290882d0ffd885 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Maintainer: Dave Wheeler <dwwheeler at gmail dot com>
# Maintainer: Eric Liu <eric at hnws dot me>
# Official repo maintainer: Massimiliano Torromeo <massimiliano dot torromeo at gmail dot com>
# Contributor: Marcello "mererghost" Rocha <https://github.com/mereghost>
# Refactored by Blaž "Speed" Hrastnik <https://github.com/archSeer>
pkgname=elasticsearch-xpack
pkgver=7.6.2
pkgrel=1
pkgdesc="Distributed RESTful search engine built on top of Lucene"
arch=('x86_64')
url="https://www.elastic.co/products/elasticsearch"
license=('custom:Elastic')
depends=('java-runtime-headless' 'systemd')
provides=('elasticsearch')
conflicts=('elasticsearch')
relpkgname=elasticsearch
source=(
"https://artifacts.elastic.co/downloads/$relpkgname/$relpkgname-$pkgver-x86_64.rpm"
elasticsearch-env
elasticsearch.service
elasticsearch@.service
elasticsearch-keystore.service
elasticsearch-keystore@.service
elasticsearch-sysctl.conf
elasticsearch-user.conf
elasticsearch-tmpfile.conf
elasticsearch.default
)
sha512sums=('4c18e59071f8f6dcb235910c79033934d45abcfaffee7e27b146771cb16ae845f33769e122416700685c69979d0516e1d9390fbe18928ca34c42220ab05c98bb'
'b25a84af32e06b2198b863d907267389485e8d595368279c953d7291aa4b479cd95050313f69e3477a1b16e4cf0a75495db7e65b96eb96f9568ed7727eec72e4'
'8280cfd911c1762a1cba67a72bf01c593dbcec00ab02b5f7ca2ef05dbcbae835f2d0e20f3143b0f601e233708e7a60148a1b2087aaff0e0b239361ca4792409f'
'712974b708f54b631d635601e7dff037a2fff0cd927cd09b27974fdb9232c1e495d70232afad5eaa4d2876665e099f880c23f914ed602700ef1962b5f137879f'
'87ff9026db8883dab2b1c5dcf7ead2700de6aa37000631d153fb61cccf7ab42edbd5eeac4e320e9d6aa2aadbe76f2c6386efb1aefde6f02aef95680f6ffafd0b'
'337c7c4c0f37430523b9a89e716051f1a05abbc71c3109dbf201bcf1b6839a88b5edb2c6498937552e8e92255e143ea344e55478543ff1c4623ed14ea04e7af1'
'4926e63ed247f9ced0674a55d01fdf7708b468a5f4b1bdb246f60c4e80d4980f21c811b952340d3e8d1c1dde77af87e062c1b66ec6818f90fb128a713c349050'
'1c1b3dfe28cd2f9026fdfa373bc59be35cf281bf22fcab12150ddded40b1355268078b9197559c4bdb9665177924fe95786028386baec90dede53264506383fd'
'6110415631909ebcf67abfaeb81ca468da17dc88ee1ea6af0625926f6fc0f189678d16817f02921a6aceccbd097a1ab801e1f63d4c3fd0ccb21e0cab4c6ee68f'
'4ef74026f82b6f0cb6cec9b992cd3f9b145083da39a37b7d8da01824c44054c72644ee0fe6d92f0329496f0fce97b7b913bca1402ef922b6cceccc360e35c5b1')
backup=('etc/elasticsearch/elasticsearch.yml'
'etc/elasticsearch/log4j2.properties'
'etc/elasticsearch/jvm.options'
'etc/default/elasticsearch')
prepare() {
cd "$srcdir"
find usr/share/elasticsearch/bin -type f ! -name \*.jar -exec \
sed -r 's;source .*/(.*)-env;source /usr/share/elasticsearch/\1-env;' -i {} +
find usr/share/elasticsearch/bin -type f -name "elasticsearch-*" ! -name elasticsearch-bin -exec \
sed 's/`dirname "$0"`/$(dirname "$(realpath "$0")")/' -i {} +
}
package() {
cd "$pkgdir"
install -dm2750 etc/elasticsearch
install -dm750 etc/elasticsearch/scripts
install -dm755 {usr/share,var/lib,var/log}/elasticsearch
install -dm755 usr/bin
cd "$srcdir"
install -Dvm644 usr/share/elasticsearch/LICENSE.txt \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
for conf in etc/elasticsearch/*; do
install -Dm644 "$conf" "$pkgdir/$conf"
done
cp -R usr/share/elasticsearch/{bin,lib,modules,plugins} "$pkgdir"/usr/share/elasticsearch
cd "$pkgdir"/usr/share/elasticsearch
rm -rf bin/elasticsearch-env
find bin/ -type f -name elasticsearch-\* ! -name elasticsearch-cli -exec \
ln -s ../share/elasticsearch/{} "$pkgdir"/usr/{} \;
ln -s ../../../var/log/elasticsearch logs
ln -s ../../../var/lib/elasticsearch data
cd "$pkgdir"
install -Dm644 "$srcdir"/elasticsearch-env usr/share/elasticsearch/elasticsearch-env
install -Dm644 "$srcdir"/elasticsearch.service usr/lib/systemd/system/elasticsearch.service
install -Dm644 "$srcdir"/elasticsearch@.service usr/lib/systemd/system/elasticsearch@.service
install -Dm644 "$srcdir"/elasticsearch-keystore.service usr/lib/systemd/system/elasticsearch-keystore.service
install -Dm644 "$srcdir"/elasticsearch-keystore@.service usr/lib/systemd/system/elasticsearch-keystore@.service
install -Dm644 "$srcdir"/elasticsearch-user.conf usr/lib/sysusers.d/elasticsearch.conf
install -Dm644 "$srcdir"/elasticsearch-tmpfile.conf usr/lib/tmpfiles.d/elasticsearch.conf
install -Dm644 "$srcdir"/elasticsearch-sysctl.conf usr/lib/sysctl.d/elasticsearch.conf
install -Dm644 "$srcdir"/elasticsearch.default etc/default/elasticsearch
}
|