blob: 425a30971b30fd51999461c3bae234b8a4789f7f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>
pkgname=electorrent
pkgver=2.7.1
pkgrel=1
pkgdesc="A remote control client for µTorrent, qBittorrent, rTorrent, Transmission, Synology & Deluge"
arch=('x86_64')
url='https://github.com/Tympanix/Electorrent'
license=('GPL3')
makedepends=('gendesk')
noextract=("${pkgname}-${pkgver}.AppImage")
source=("${pkgname}-${pkgver}.AppImage::https://github.com/tympanix/Electorrent/releases/download/v${pkgver}/Electorrent-${pkgver}.AppImage")
sha256sums=('3197b0373667dee043b7a649dbb9a41884fd0726c49d6bfa303a50273d9309db')
package() {
chmod 755 ./${pkgname}-${pkgver}.AppImage
./${pkgname}-${pkgver}.AppImage --appimage-extract
install -Dm644 squashfs-root/usr/share/icons/hicolor/512x512/apps/electorrent.png "${pkgdir}/usr/share/pixmaps/electorrent.png"
gendesk -f -n --pkgname "${pkgname}" \
--pkgdesc "$pkgdesc" \
--name "Electorrent" \
--comment "$pkgdesc" \
--exec "${pkgname}" \
--categories 'Utility;Network;Application' \
--icon "${pkgname}"
install -Dm644 "${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
install -d "${pkgdir}/usr/bin"
install -d "${pkgdir}/opt"
cp -avR squashfs-root/ "${pkgdir}/opt/${pkgname}"
ln -s /opt/${pkgname}/AppRun "${pkgdir}/usr/bin/electorrent"
find "${pkgdir}/opt/${pkgname}" -type d -exec chmod 755 {} +
}
|