blob: 240a18239b8478e75a2647e5740a66c2e102ec64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: Matthew Tran <0e4ef622@gmail.com>
# Contributor: Marcel O'Neil <marcel at marceloneil dot com>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
# Contributor: RunningDroid <runningdroid AT zoho.com>
# Contributor: Sebastian Lindqvist <dunpin@gmail.com>
# Contributor: Dan Beste <dan.ray.beste@gmail.com>
pkgname='electron-cash-git'
pkgdesc='Lightweight Bitcoin Cash wallet'
pkgver=4.3.1.r92.g3f885aae7
pkgrel=1
url='http://www.electroncash.org/'
arch=('any')
license=('MIT')
makedepends=(
'automake'
'autoconf'
'git'
'protobuf'
'python-requests'
'python-setuptools'
'python-tox'
)
depends=(
'hicolor-icon-theme'
'python'
'python-certifi'
'python-dateutil'
'python-dnspython'
'python-ecdsa'
'python-jsonrpclib-pelix'
'python-pathvalidate>=3.0.0'
'python-protobuf'
'python-pyaes'
'python-pyqt5'
'python-pysocks'
'python-qrcode'
'python-requests'
'python-six'
'python-stem'
'qt5-base'
'qt5-svg'
'ttf-bitstream-vera'
)
optdepends=(
'tor: Tor support'
'python-btchip: Ledger hardware wallet support'
'python-hidapi: Digital Bitbox hardware wallet support'
'python-matplotlib: plot transaction history in graphical mode'
'python-pycryptodomex: use PyCryptodome AES implementation instead of pyaes'
'python-qdarkstyle: optional dark theme in graphical mode'
'python-rpyc: send commands to Electrum Python console from an external script'
'python-trezor: Trezor hardware wallet support'
'python-keepkey: Trezor hardware wallet support'
'zbar: QR code reading support'
)
provides=("${pkgname/-git/}")
conflicts=("${pkgname/-git/}")
source=("${pkgname}::git+https://github.com/Electron-Cash/Electron-Cash.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname}"
git describe --long --tags \
| sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${pkgname}"
# Compile the icons file for Qt:
pyrcc5 icons.qrc -o electroncash_gui/qt/icons_rc.py
# Compile the protobuf description file:
protoc --proto_path=electroncash/ --python_out=electroncash/ electroncash/paymentrequest.proto
protoc --proto_path=electroncash_plugins/fusion/protobuf/ --python_out=electroncash_plugins/fusion/ electroncash_plugins/fusion/protobuf/fusion.proto
# Create translations (optional):
python contrib/make_locale
# Use libsecp
bash contrib/make_secp
# Build
python setup.py build
}
check() {
cd "${pkgname}"
tox -e py311 -- --ignore-glob='*regtest*'
}
package() {
cd "${pkgname}"
python setup.py install --root="${pkgdir}" --optimize=1
}
# vim: ts=2 sw=2 et:
|