blob: 5cccc95892fc50a15999a5c51a9c1daf0e4aa4bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Maintainer: Dan Beste <dan.ray.beste@gmail.com>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
# Contributor: RunningDroid <runningdroid AT zoho.com>
# Contributor: Sebastian Lindqvist <dunpin@gmail.com>
#
# ThomasV PGP key: gpg --recv-key 6694D8DE7BE8EE5631BED9502BD5824B7F9470E6
# http://bitcoin-otc.com/viewgpg.php?nick=ThomasV
#
pkgname='electron-cash-git'
pkgdesc='Lightweight Bitcoin Cash wallet'
pkgver=3.1.2.r4.g37a2e9d2
pkgrel=1
url='http://www.electroncash.org/'
install="${pkgname}.install"
arch=('any')
license=('MIT')
makedepends=(
'git'
'protobuf'
'python-requests'
'python-setuptools'
'python-tox'
)
depends=(
'hicolor-icon-theme'
'python'
'python-dnspython'
'python-ecdsa'
'python-jsonrpclib-pelix'
'python-pbkdf2'
'python-protobuf'
'python-pyaes'
'python-pyqt5'
'python-pysocks'
'python-qrcode'
'python-requests'
'python-six'
'qt5-base'
)
optdepends=(
'desktop-file-utils: update desktop icon'
'gtk-update-icon-cache: update desktop icon'
'python-btchip: Ledger hardware wallet support'
'python-pycryptodomex: use PyCryptodome AES implementation instead of pyaes'
'python-matplotlib: plot transaction history in graphical mode'
'python-rpyc: send commands to Electrum Python console from an external script'
'xdg-utils: update desktop icon'
'zbar: QR code reading support'
)
provides=("${pkgname/-git/}")
conflicts=("${pkgname/-git/}")
source=(
"${pkgname}::git+https://github.com/fyookball/electrum.git"
"${pkgname}.install"
)
sha256sums=(
'SKIP'
'd682766321f9981ee38aee26dc050209882d8c1c6006e3e509649b47fa1bb073'
)
install="${pkgname}.install"
pkgver() {
cd "${pkgname}"
git describe --long --tags \
| sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${pkgname}"
# Compile the icons file for Qt:
pyrcc5 icons.qrc -o gui/qt/icons_rc.py
# Compile the protobuf description file:
protoc --proto_path=lib/ --python_out=lib/ lib/paymentrequest.proto
# Create translations (optional):
python contrib/make_locale
# Build
python setup.py build
}
check() {
cd "${pkgname}"
tox -e py36
}
package() {
cd "${pkgname}"
python setup.py install --root="${pkgdir}" --optimize=1
}
# vim: ts=2 sw=2 et:
|