blob: 053d5f80ebb30bc4ab975fb7b43d9a25690c91fa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
_projectname=electron
_major=13
_pkgname="${_projectname}${_major}"
_pkgver="${_major}.5.1"
pkgver="${_pkgver/-/.}"
pkgname="${_pkgname}-bin"
pkgrel=1
pkgdesc="Build cross platform desktop apps with web technologies - version ${_major} - binary version"
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url=https://electronjs.org/
license=('MIT')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libnghttp2' 'libxslt' 'minizip'
'nss' 're2' 'snappy')
optdepends=('kde-cli-tools: file deletion support (kioclient5)'
'libappindicator-gtk3: StatusNotifierItem support'
'pipewire: WebRTC desktop sharing under Wayland'
'trash-cli: file deletion support (trash-put)'
"xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
source_x86_64=(
"${pkgname}-chromedriver-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
"${pkgname}-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
)
source_i686=(
"${pkgname}-chromedriver-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-ia32.zip"
"${pkgname}-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-ia32.zip"
)
source_armv7h=(
"${pkgname}-chromedriver-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-armv7l.zip"
"${pkgname}-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-armv7l.zip"
)
source_aarch64=(
"${pkgname}-chromedriver-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
"${pkgname}-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
)
sha256sums_x86_64=('0c649af8cc526fe838ba9fe98cffa9b2e9500fb9422ee79eeef65ffc00fe4711'
'4d145dbca59541d665435198c9fb697b1ec85c6e525878b7f48ecb8431dc4836')
sha256sums_i686=('b0d4c6eab101f20c0bcf9e11f4732aef28fe1c0394a42c8382f002f8e92472fb'
'95acabcf7d0a5a3bbfa0634c1956d8aea59565fb695d22ec65edd77c2a09e3a8')
sha256sums_armv7h=('3353136e8f2d02c2a16e90db560f3875af6991d0198b925d3eeae914fedf7ae8'
'9cb773eaa9882c313513cb1bb552f8bcac859f35854de477dc2ec6cc24e7d003')
sha256sums_aarch64=('2612d1ea6f0f1dcee6cc7d88b077c7feff554962b3e2de3442e82175c6822da8'
'ae605f169482b1c40e9449073c0f962cceeac4166a00cb304ba22f4f5a7a5d48')
package() {
install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
for _folder in 'locales' 'resources' 'swiftshader'; do
cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
done
chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
install -dm755 "${pkgdir}/usr/bin"
ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
for _license in 'LICENSE' 'LICENSES.chromium.html'; do
install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
done
}
|