blob: 4252bc259e46294d309958b3e6e6b88d26f99d5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
# Based on aur/electron8-bin by Tom Vincent <http://tlvince.com/contact>
# Based on extra/electron19 by
# Bruno Pagani <archange@archlinux.org>
# Caleb Maclennan <caleb@alerque.com>
# https://releases.electronjs.org/
_pkgver=19.1.9
pkgrel=2
pkgver="${_pkgver/-/.}"
_major_ver=${pkgver%%.*}
_projectname=electron
_pkgname="${_projectname}${_major_ver}"
pkgname="${_pkgname}"-bin
pkgdesc='Build cross platform desktop apps with web technologies'
pkgdesc+=' — binary'
arch=(x86_64 armv7h aarch64)
url='https://electronjs.org'
license=(MIT BSD-3-Clause)
depends=(
alsa-lib # libasound.so.2
gcc-libs # libgcc_s.so
glibc # libc.so libm.so
gtk3 libgtk-3.so
nss # libnss3.so
)
optdepends=('kde-cli-tools: file deletion support (kioclient5)'
'pipewire: WebRTC desktop sharing under Wayland'
'trash-cli: file deletion support (trash-put)'
'xdg-utils: open URLs with desktop’s default (xdg-email, xdg-open)')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
source_aarch64=(
"${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
"${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
)
source_armv7h=(
"${_releaseurl}/chromedriver-v${_pkgver}-linux-armv7l.zip"
"${_releaseurl}/${_projectname}-v${_pkgver}-linux-armv7l.zip"
)
source_x86_64=(
"${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
"${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
)
sha256sums_x86_64=('6b066a9784e86e8710ccbf6224ca143b12d0f3b2988c34a4852d0d1002bb08a6'
'fd320675f1647e03d96764a906c51c567bf0bcbe0301550e4559d66dd76796df')
sha256sums_armv7h=('cb46629e77f20c40b6c48ab485410204f8d22001b5d94f002590fc9d357cabb6'
'90b4afbf03dde52953ada2d7082fed9a8954e7547d1d93c6286ba04f9ef68987')
sha256sums_aarch64=('72d48a1d35ee2b952ce79d7786bc82dd12b54adfb7ad96a6a0cb5c11f512c47e'
'473e07a6db8a92d4627ef1012dda590c5a04fb3d9804cc5237b033fdb6f52211')
package() {
install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
for _folder in 'locales' 'resources'; do
cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
done
chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
install -dm755 "${pkgdir}/usr/bin"
ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
for _license in 'LICENSE' 'LICENSES.chromium.html'; do
install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
done
}
|