blob: 50ac6b718c591226682f4787b94e9a39a0d8aa06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Co-Maintainer: wcyat <wcyat at wcyat dot me>
pkgname=electronmail
pkgver=5.2.2
pkgrel=2
_electronversion=27
pkgdesc="Unofficial ProtonMail Desktop App"
arch=('x86_64')
url="https://github.com/vladimiry/ElectronMail"
license=('GPL-3.0-or-later')
depends=("electron${_electronversion}" 'libsecret')
makedepends=('git' 'libxcrypt-compat' 'npm' 'pnpm' 'python-setuptools' 'yarn')
optdepends=('org.freedesktop.secrets: password storage backend')
source=("git+https://github.com/vladimiry/ElectronMail.git#tag=v$pkgver"
"$pkgname.desktop"
"$pkgname.sh")
sha256sums=('558ffcbfc83bd16d0abff2788c7447f7eaf82d3a8f45dd890632b2999fb3ee98'
'c95c69f1d0db27180236ff063d9563da8750ecce81883adfb217b73ac3bb974e'
'e7e9dd6e065118ae5d9624c7c81328086719fab198d30a92b08979c29757a3b2')
prepare() {
cd ElectronMail
sed -i "s|@ELECTRONVERSION@|${_electronversion}|" "$srcdir/$pkgname.sh"
}
build() {
cd ElectronMail
export PNPM_HOME="$srcdir/pnpm-home"
export npm_config_cache="$srcdir/npm_cache"
export YARN_CACHE_FOLDER="$srcdir/yarn-cache"
export PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD=1
electronDist="/usr/lib/electron${_electronversion}"
electronVer="$(sed s/^v// /usr/lib/electron${_electronversion}/version)"
pnpm install --frozen-lockfile
pnpm app:dist
npm exec --package=electron-builder -- electron-builder --linux pacman \
-c.electronDist=$electronDist -c.electronVersion=$electronVer
}
package() {
cd ElectronMail
install -Dm644 dist/linux-unpacked/resources/app.asar -t "$pkgdir/usr/lib/$pkgname/"
cp -r dist/linux-unpacked/resources/app.asar.unpacked -t "$pkgdir/usr/lib/$pkgname/"
for i in 16 24 32 48 64 128 256 512 1024; do
install -Dm644 app/assets/icons/png/${i}x${i}.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/$pkgname.png"
done
install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications/"
}
|