blob: bae69baf86f7df3dc8a8dc5c2dc60028f3faf04c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>
_pkgname=electronplayer
pkgname=$_pkgname
pkgver=2.0.4
pkgrel=2
pkgdesc="An Electron-based web video player, supporting multiple services"
arch=(any)
url="https://github.com/oscartbeaumont/ElectronPlayer"
license=("MIT" "custom")
depends=("c-ares"
"ffmpeg"
"gtk3"
"http-parser"
"libevent"
"libnghttp2"
"libxslt"
"libxss"
"minizip"
"nss"
"re2"
"snappy"
"glibc"
"alsa-lib")
makedepends=("yarn"
"npm")
optdepends=("libpulse: For pulseaudio support")
provides=("$_pkgname")
conflicts=("$_pkgname-git")
source=("https://github.com/oscartbeaumont/ElectronPlayer/archive/v${pkgver}.tar.gz"
"${_pkgname}.desktop")
sha512sums=('d0e29f3290a2eb5a54a245c3dd87139b7758772320ab5efd0d93d3ca90904b43549c58635b1e352c16c161b68f26a09e1b11c98eae68c273db300236bca490a4'
'280a252895e641f4bd009b4acf7f9f42959f0b9d51424ea71bf564600533de3867a652efd9d982643c34907bb5e57fa677e6c73315cb69a2f12dfd52e6f09f03')
prepare() {
cd "ElectronPlayer-$pkgver"
yarn --cache-folder "${srcdir}/yarn-cache"
}
build() {
cd "ElectronPlayer-$pkgver"
# We are not using system Electron as we need widevinecdm and an older Electron version
npx electron-builder --linux dir
# Delete darwin (macOS) widevine libs
rm -rf "dist/linux-unpacked/resources/app.asar.unpacked/node_modules/electron-widevinecdm/widevine/darwin_x64"
}
package() {
cd "ElectronPlayer-$pkgver"
install -d "${pkgdir}/opt/${_pkgname}/" "${pkgdir}/usr/bin" "${pkgdir}/usr/share/doc" "${pkgdir}/usr/share/licenses"
cp -r dist/linux-unpacked/* "${pkgdir}/opt/${_pkgname}/"
chmod +x "${pkgdir}/opt/${_pkgname}/electronplayer"
ln -s "/opt/${_pkgname}/electronplayer" "${pkgdir}/usr/bin/electronplayer"
install -Dm 644 "build/icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
install -Dm 644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -Dm 644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
ln -s "/opt/${_pkgname}/LICENSE.electron.txt" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE.electron.txt"
ln -s "/opt/${_pkgname}/LICENSES.chromium.html" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSES.chromium.html"
}
|