blob: 4f2b330a3d2bf8f0c75b8ccdc75f460d6ee11954 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
pkgname=electrum-ltc-git
pkgver=3.2.3.git20180925.8044dc1
pkgrel=1
pkgdesc='Litecoin thin client'
arch=(any)
url=https://electrum-ltc.org/
license=(MIT)
depends=(desktop-file-utils
libsecp256k1
python-btchip
python-dnspython
python-ecdsa
python-jsonrpclib-pelix
python-matplotlib
python-protobuf
python-pyaes
python-pycryptodomex
python-pyqt5
python-pysocks
python-qrcode
python-requests
python-scrypt
python-websocket-client
zbar)
makedepends=(git)
source=(git+https://github.com/pooler/electrum-ltc.git)
sha256sums=(SKIP)
pkgver() {
cd electrum-ltc
printf %s.git%s "$(grep -om1 '[0-9.]*' electrum_ltc/version.py)" \
"$(git log -1 --format=%ad.%h --date=format:%Y%m%d --abbrev=7)"
}
prepare() {
sed -e 's/Exec=.*electrum-ltc %u"/Exec=electrum-ltc %u/' \
-e 's/Exec=.*electrum-ltc --testnet %u"/Exec=electrum-ltc --testnet %u/' \
-i electrum-ltc/electrum-ltc.desktop
}
build() {
cd electrum-ltc
pyrcc5 icons.qrc >electrum_ltc/gui/qt/icons_rc.py
protoc --proto_path=electrum_ltc --python_out=electrum_ltc electrum_ltc/paymentrequest.proto
contrib/make_locale
./setup.py build
}
package() {
cd electrum-ltc
./setup.py install -O1 --root="$pkgdir"
install -Dm644 AUTHORS README.rst RELEASE-NOTES electrum-ltc.conf.sample \
-t "$pkgdir"/usr/share/doc/electrum-ltc
install -Dm644 LICENCE -t "$pkgdir"/usr/share/licenses/$pkgname
}
|