blob: 5d207c09331e96d756b3366d3e682f42159c2f55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Contributor: Kyle Keen <keenerd@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Ben <contrasutra@myrealbox.com>
# Maintainer: ferreum <code.danielk at gmail com>
_pkgname=elinks
pkgname=${_pkgname}-git
pkgver=v0.14.1.r0.g9e0c85e5
pkgrel=1
pkgdesc="An advanced and well-established feature-rich text mode web browser. Git version."
arch=(i686 x86_64 armv6h armv7h aarch64)
url="https://github.com/rkd77/elinks"
provides=(${_pkgname})
license=('GPL')
conflicts=(${_pkgname})
depends=('bzip2' 'expat>=2.0' 'gpm>=1.20.4' 'openssl' 'lua51' 'libidn' 'gc' 'tre' 'zlib')
source=("git+https://github.com/rkd77/elinks#branch=elinks-0.14")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --tags --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${_pkgname}"
# not needed when using autoreconf
#[ -x configure ] || sh autogen.sh
# autoreconf to allow compiling on arm (project's config is outdated (updated 2004)?)
autoreconf -ifv
./configure --prefix=/usr --mandir=/usr/share/man \
--sysconfdir=/etc \
--with-zlib \
--without-lzma \
--without-bzlib \
--without-x \
--without-spidermonkey \
--enable-cgi \
--enable-leds \
--disable-smb \
--disable-sm-scripting \
--enable-256-colors \
--enable-html-highlight \
--enable-exmode
make
}
package() {
cd "${_pkgname}"
make DESTDIR="$pkgdir" install
rm -f "$pkgdir/usr/share/locale/locale.alias"
}
# vim:set sw=2 sts=0 et:
|