blob: 37e8ee44ae7d545ee08777bc445a8ba2853e7df7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: KokaKiwi <kokakiwi@kokakiwi.net>
pkgname=elixir-ls
pkgver=0.23.0
pkgrel=1
pkgdesc='A frontend-independent Language Server Protocol for Elixir'
url='https://github.com/elixir-lsp/elixir-ls'
license=('Apache-2.0')
arch=('any')
depends=('elixir' 'erlang-nox')
makedepends=('git' 'rebar3')
source=("elixir-ls-$pkgver.tar.gz::https://github.com/elixir-lsp/elixir-ls/archive/v$pkgver.tar.gz")
sha256sums=('83c49ec9268ad76f9b7f72585e3cb9dd0199338be69a9ebf507d77109c6a5684')
b2sums=('5aa0894a2ae6aebaaf0da96a1f4bfeaf39699b5c905618cd07777cfbef14acff996d8276f7d9c81badb7eef80c442d9c21f6468849e3e630e666ca04c4510414')
build() {
cd "$pkgname-$pkgver"
export MIX_ENV=prod
export MIX_HOME="$srcdir/mix-cache"
# Fetch hex+rebar for deps.get to work
mix local.hex --force
mix local.rebar --force rebar3 /usr/bin/rebar3
mix deps.get
mix compile
}
package() {
cd "$pkgname-$pkgver"
export MIX_ENV=prod
install -dm0755 "$pkgdir"/usr/lib/$pkgname
mix elixir_ls.release2 -o "$pkgdir"/usr/lib/$pkgname
install -dm0755 "$pkgdir"/usr/bin
echo -e "#!/bin/sh\nexec /usr/lib/$pkgname/language_server.sh" > "$pkgdir"/usr/bin/elixir-ls
echo -e "#!/bin/sh\nexec /usr/lib/$pkgname/debugger.sh" > "$pkgdir"/usr/bin/elixir-ls-debug
chmod +x "$pkgdir"/usr/bin/*
}
|