blob: ef1bc4db1d481bad71b126e845bf174a1e5b0d8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Haochen Tong <i at hexchain dot org>
pkgname=elvish-git
_pkgname=elvish
pkgver=0.14.0.r20.gd2e72011
pkgrel=1
pkgdesc="A friendly and expressive Unix shell."
arch=('i686' 'x86_64')
url="https://github.com/elves/elvish"
license=('custom:2-clause BSD')
provides=('elvish')
conflicts=('elvish')
depends=('glibc')
makedepends=('git' 'go')
source=("git+https://github.com/elves/elvish.git")
md5sums=('SKIP')
install=elvish.install
pkgver() {
cd "$_pkgname"
( set -o pipefail;
git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
mkdir -p "$srcdir/build"
export GOPATH="$srcdir/build"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=vendor -modcacherw"
cd "$srcdir/elvish"
go mod vendor
}
build() {
export GOPATH="$srcdir/build"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=vendor -modcacherw"
cd "$srcdir/elvish"
go build -v -ldflags="-X github.com/elves/elvish/pkg/buildinfo.Version=$pkgver" .
cd website
mkdir "$srcdir/doc"
go build -v ./cmd/elvdoc/
for file in builtin edit epm language math platform readline-binding re store str unix; do
./elvdoc -filter < "ref/$file.md" | pandoc \
-s -f gfm -t man -V section:7 \
-V header:"Miscellaneous Information Manual" \
-V footer:"Elvish $pkgver" -M date:"$(date -u --date=@${SOURCE_DATE_EPOCH} "+%b %d, %Y")" \
-M title:"elvish-$file" \
-o "$srcdir/doc/elvish-$file.7"
done
}
check() {
export GOPATH="$srcdir/build"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-trimpath -mod=vendor -modcacherw"
cd "$srcdir/elvish"
make test
}
package() {
install -Dm755 "$srcdir/elvish/elvish" -t "$pkgdir/usr/bin/"
install -Dm644 "$srcdir/elvish/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
install -dm755 "$pkgdir/usr/share/man/man7"
cp -rv --no-preserve=ownership "$srcdir/doc/"* "$pkgdir/usr/share/man/man7"
}
|