blob: 683bcbd3cf850d9fdb0e38995b5f11dee94ca62f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Contributor: Jamie Beardslee
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=emacs-application-framework-git
pkgver=r1801.8ac098b
pkgrel=1
pkgdesc="EAF extends GNU Emacs to an entire universe of powerful GUI applications."
arch=('any')
url="https://github.com/manateelazycat/emacs-application-framework"
license=('GPL3')
depends=('emacs' 'python-epc' 'python-pyqt5' 'python-pyqt5-sip' 'python-pyqtwebengine' 'wmctrl' 'xdotool' 'nodejs')
optdepends=('python-pymupdf: EAF PDF Viewer support'
'python-qrcode: EAF File Sender/File Receiver/Airshare support'
'libreoffice: EAF Doc Viewer support'
'filebrowser-bin: EAF File Browser support'
'python-qtconsole: EAF Jupyter support'
'python-retrying: EAF Markdown Previewer support')
makedepends=('git')
provides=('emacs-eaf')
conflicts=('emacs-eaf')
source=("git+https://github.com/manateelazycat/emacs-application-framework")
md5sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
cd "${pkgname%-git}"
install -d "$pkgdir"/usr/share/emacs/site-lisp/eaf/
for _i in app core docker *.el *.py
do
cp -r ${_i} "$pkgdir"/usr/share/emacs/site-lisp/eaf/
done
install -Dm644 README.md "$pkgdir"/usr/share/doc/emacs-eaf/README.md
}
|