blob: 048f3e7f7e5141537b379345328c3e8ad034070b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Maintainer: sballert <sballert@posteo.de>
_gituser="magnars"
_gitrepo="dash.el"
pkgname=emacs-dash-git
pkgver=2.13.0.92.g6514359
pkgrel=1
pkgdesc='A modern list API for Emacs. No cl required'
arch=('any')
url="https://github.com/${_gituser}/${_gitrepo}"
license=('GPL')
depends=('emacs')
makedepends=('git')
conflicts=('emacs-dash')
provides=('emacs-dash')
source=("git+https://github.com/${_gituser}/${_gitrepo}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_gitrepo}"
git describe | tr - .
}
build() {
cd "${_gitrepo}"
emacs -Q -batch -L . -f batch-byte-compile dash{,-functional}.el
}
package() {
cd "${_gitrepo}"
install -d "$pkgdir"/usr/share/emacs/site-lisp/dash/
install -Dm644 dash{,-functional}.{el,elc} "$pkgdir"/usr/share/emacs/site-lisp/dash/
install -Dm644 dash.info "$pkgdir"/usr/share/info/dash.info
}
|