PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=emacs-else-git 
pkgver=2014_02_14
pkgrel=4
pkgdesc="Emacs Language Sensitive Editor -- minor mode to use language specific abbreviations"
url="http://home.comcast.net/~dharter46"
arch=('any')
license=('GPL')
depends=('emacs')
install=else.install
source=('git+https://gitlab.com/stefanhusmann/emacs-else.git')
md5sums=('SKIP')

pkgver(){
  cd "$srcdir"/emacs-else
  git log -1 --format="%cd" --date=short | tr - _ 
}

build() {
  cd "$srcdir"/emacs-else
  makeinfo else.texi 
  texi2pdf else.texi 
  sed -i 's/string-to-int/string-to-number/g' setnu.el 
  for _i in *.el
  do
    emacs -batch -q -f batch-byte-compile ${_i}
  done 
}

package() {
  cd "$srcdir"/emacs-else
  install -Dm644 else "$pkgdir"/usr/share/info/else.info 
  install -Dm644 else.pdf \
    "$pkgdir"/usr/share/doc/$pkgname/$pkgname.pdf 
  install -d "$pkgdir"/usr/share/emacs/site-lisp 
  for _i in *.lse *.el *.elc
  do 
    install -Dm644 ${_i} "$pkgdir"/usr/share/emacs/site-lisp
  done 
}