1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
|
# Maintainer: Pedro A. López-Valencia <https://aur.archlinux.org/users/vorbote>
#######################################################################
# CAVEAT LECTOR
#######################################################################
#
# Don't run this on a tmpfs unless you have oodles of RAM.
# When the official git repo started, the size was about
# 200MB. As time passes, it is growing more and more.
# Final directory size after a build is shy of 1Gb!
# Furthermore, the FSF isn't precisely rich and Savannah
# network costs aren't cheap. Keep your git checkout!
#
# Keeping this directory in a safe place preserves the
# git repo and the src dir for faster compilation if
# you want. You may delete the pkg dir after successfully
# creating a package.
#
# "makepkg -i" is your friend.
#
#######################################################################
#######################################################################
#
# Still reading? Here kid, have enough rope to hang yourself. :-)
#
#######################################################################
#######################################################################
# Assign "YES" to the variable you want enabled, empty otherwise
#######################################################################
GTK3="" # Leave empty to compile with gtk+ 2 support.
LTO= # Enable link-time optimization. Broken.
CAIRO= # Very broken for me. Use at own risk.
XWIDGETS= # Use GTK+ native widgets pulled from webkitgtk.
DOCS_HTML= # Generate and install html documentation.
DOCS_PDF= # Generate and install pdf documentation.
#######################################################################
_pkgname=('emacs-git')
pkgname=("$_pkgname-gtk2" "$_pkgname-docs")
pkgver=25.1.r1
pkgrel=1
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/emacs/"
_savannah="git://git.savannah.gnu.org/emacs.git"
_github="git+https://github.com/emacs-mirror/emacs.git"
license=('GPL')
makedepends=('git')
source=("${_pkgname}::${_github}")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/${_pkgname}"
_basever="$(git describe --tags `git rev-list --tags --max-count=1`)"
_minver="${_basever//emacs-/}"
_minver="${_minver//-/.}"
printf "%s.r%s" \
"${_minver}" \
"$(git rev-list --count ${_basever}..HEAD)"
}
# There is no need to run autogen.sh after first checkout.
# Doing so, breaks incremental compilation.
prepare() {
cd "$srcdir/${_pkgname}"
[[ -x configure ]] || ./autogen.sh
}
build() {
cd "$srcdir/${_pkgname}"
# Avoid hardening-wrapper (taken from emacs-pretest, thanks to Thomas Jost).
export PATH=$(echo "$PATH" | sed 's!/usr/lib/hardening-wrapper/bin!!g')
local _conf=(
--prefix=/usr
--sysconfdir=/etc
--libexecdir=/usr/lib
--localstatedir=/var
--mandir=/usr/share/man
--with-gameuser=:games
--with-sound=alsa
--with-xft
--with-modules)
#######################################################################
#######################################################################
if [[ $GTK3 = "YES" ]]; then
_conf+=('--with-x-toolkit=gtk3' '--without-gconf' '--with-gsettings');
else
_conf+=('--with-x-toolkit=gtk2' '--with-gconf' '--without-gsettings');
fi
if [[ $LTO = "YES" ]]; then _conf+=('--enable-link-time-optimization'); fi
if [[ $CAIRO = "YES" ]]; then _conf+=('--with-cairo'); fi
if [[ $XWIDGETS = "YES" ]]; then _conf+=('--with-xwidgets'); fi
#######################################################################
#######################################################################
./configure "${_conf[@]}"
# Using "make" instead of "make bootstrap" enables incremental
# compiling. Less time recompiling. Yay! But if you may
# need to use bootstrap sometime, just add it to the command
# line.
# Please note that incremental compilation implies that you
# are reusing your src directory!
make
make html
make pdf
# You may need to run this if loaddefs.el files become
# corrupt.
#cd "$srcdir/${_pkgname}/lisp"
#make autoloads
#cd ../
}
package_emacs-git-gtk2() {
pkgdesc="GNU Emacs, the extensible self-documenting text editor — built from git sources."
depends=('gpm' 'giflib' 'm17n-lib' 'desktop-file-utils' 'alsa-lib' 'imagemagick' 'gtk2')
conflicts=('emacs' 'emacs-git')
provides=('emacs')
cd "$srcdir/${_pkgname}"
make DESTDIR="$pkgdir/" install
# remove conflict with ctags package
mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
mv "$pkgdir"/usr/share/man/man1/{ctags.1.gz,ctags.emacs.1.gz}
# remove conflict with texinfo
rm "$pkgdir"/usr/share/info/info.info.gz
# fix user/root permissions on usr/share files
find "$pkgdir"/usr/share/emacs/ | xargs chown root:root
# fix permssions on /var/games
mkdir -p "$pkgdir"/var/games/emacs
chmod 775 "$pkgdir"/var/games
chmod 775 "$pkgdir"/var/games/emacs
chown -R root:games "$pkgdir"/var/games
}
package_emacs-git-docs() {
pkgdesc="GNU Emacs, built from git sources — HTML and PDF documentation package."
makedepends+=('texlive-core')
provides=('emacs-docs')
conflicts=('emacs-docs')
cd "$srcdir/${_pkgname}"
make DESTDIR="$pkgdir/" install-html
make DESTDIR="$pkgdir/" install-pdf
}
|