summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9c17682a04ca6ebd4f851cfc976f7cc088dddc1b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: sballert <sballert@posteo.de>

_gituser="emacscollective"
_gitrepo="no-littering"

pkgname=emacs-no-littering-git
pkgver=r144.3f6d290
pkgrel=1
pkgdesc="Help keeping ~/.emacs.d clean"
url="https://github.com/${_gituser}/${_gitrepo}"
arch=('any')
license=('GPL3')
depends=('emacs')
makedepends=('git')
provides=('emacs-no-littering')
conflicts=('emacs-no-littering')
source=("git+https://github.com/${_gituser}/${_gitrepo}.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_gitrepo"
  printf "r%s.%s" $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}

build() {
  cd "$_gitrepo"
  emacs -q --no-splash -batch -L . -f batch-byte-compile *.el
}

package() {
  cd "$_gitrepo"
  install -d  "$pkgdir"/usr/share/emacs/site-lisp/${_gitrepo}/
  install -m644 *.el{c,} "$pkgdir"/usr/share/emacs/site-lisp/${_gitrepo}/
}