blob: 06793b6786b089d45ca2cedda1f956dec90d03a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Contributor: Davor Balder <dbalder@ozemail.com.au>
# Contributor: Jiyunatori <tori_LEAVETHISOUT_@0xc29.net>
# Contributor: mdev
# Maintainer: gryffyn <aur@evan.mp>
pkgname=emacs-org-mode
_srcname=org
pkgver=9.4.4
pkgrel=1
pkgdesc="Emacs Org Mode"
arch=('any')
url="http://orgmode.org/"
depends=('emacs')
optdepends=('java-runtime: For using ditaa.jar in the contrib directory'
'zsh: for using dir2org.zsh in the contrib directory')
license=('GPL')
install=emacs-org-mode.install
source=("http://orgmode.org/$_srcname-$pkgver.tar.gz")
sha256sums=('028be6615587693698e50d8d51186da87766547b37fd84af6f5c2e2146b2324a')
build() {
cd "$_srcname-$pkgver"
make
}
package() {
cd "$_srcname-$pkgver"
make DESTDIR="$pkgdir" install
## by default now we install also the contrib directory
install -d -m755 "$pkgdir"/usr/share/emacs/site-lisp/org_contrib
cp -r contrib/* "$pkgdir"/usr/share/emacs/site-lisp/org_contrib
##! proper install of info files (thanks mdev)
##! replace "orgmode" with "org" in the following lines if you want
##! to replace emacs own org's info files. You also need to change the .install.
install -D -m644 doc/org "$pkgdir"/usr/share/info/orgmode
gzip -9 "$pkgdir"/usr/share/info/orgmode
rm "$pkgdir"/usr/share/info/org
}
|